mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 20:59:41 +02:00
7b002ac180
Minor update bringing in new features, improvements and bug fixes. Most notable changes: - vbox: removed support for version 5.0 and 5.1 APIs - vbox: added support for version 6.0 and 6.1 APIs - qemu: Various embed driver fixes - qemu: Add virtiofs support - qemu: support disabling hotplug/unplug of PCIe devices - xen: Add support for 'passthrough' hypervisor feature Straightforward uprev, requiring patch refreshes to remove fuzz. Build and runtime behaviour is identical to older version v6.1.0. ptest summary: =================================== Testsuite summary for libvirt 6.3.0 =================================== - TOTAL: 129 - PASS: 123 - SKIP: 1 - XFAIL: 0 - FAIL: 5 - XPASS: 0 - ERROR: 0 Failed test: - virschematest - domaincapstest - qemuxml2argvtest - qemuhotplugtest - virsh-auth Signed-off-by: Sakib Sajal <sakib.sajal@windriver.com> Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
63 lines
2.1 KiB
PHP
63 lines
2.1 KiB
PHP
inherit python3native python3-dir
|
|
|
|
export STAGING_INCDIR
|
|
export STAGING_LIBDIR
|
|
export BUILD_SYS
|
|
export HOST_SYS
|
|
|
|
RDEPENDS_${PN}-python += "python3"
|
|
PACKAGECONFIG_${PN}-python[xen] = ",,,xen-python"
|
|
|
|
PACKAGES += "${PN}-python-staticdev ${PN}-python-dev ${PN}-python-dbg ${PN}-python"
|
|
|
|
FILES_${PN}-python-staticdev += "${PYTHON_SITEPACKAGES_DIR}/*.a"
|
|
FILES_${PN}-python-dev += "${PYTHON_SITEPACKAGES_DIR}/*.la"
|
|
FILES_${PN}-python-dbg += "${PYTHON_SITEPACKAGES_DIR}/.debug/"
|
|
FILES_${PN}-python = "${bindir}/* ${libdir}/* ${libdir}/${PYTHON_DIR}/*"
|
|
|
|
SRC_URI += "http://libvirt.org/sources/python/libvirt-python-${PV}.tar.gz;name=libvirt_python"
|
|
|
|
SRC_URI[libvirt_python.md5sum] = "4cf898350ee9a47f94986d402c153bdb"
|
|
SRC_URI[libvirt_python.sha256sum] = "c772421ecc144f098f4ab15db700c62db9b9e6e76b876217edcfd62e9ce02750"
|
|
|
|
export LIBVIRT_API_PATH = "${S}/docs/libvirt-api.xml"
|
|
export LIBVIRT_CFLAGS = "-I${S}/include"
|
|
export LIBVIRT_LIBS = "-L${B}/src/.libs -lvirt -ldl"
|
|
export LDFLAGS="-L${B}/src/.libs"
|
|
|
|
LIBVIRT_INSTALL_ARGS = "--root=${D} \
|
|
--prefix=${prefix} \
|
|
--install-lib=${PYTHON_SITEPACKAGES_DIR} \
|
|
--install-data=${datadir}"
|
|
|
|
python __anonymous () {
|
|
pkgconfig = d.getVar('PACKAGECONFIG')
|
|
if ('python') in pkgconfig.split():
|
|
d.setVar('LIBVIRT_PYTHON_ENABLE', '1')
|
|
else:
|
|
d.setVar('LIBVIRT_PYTHON_ENABLE', '0')
|
|
}
|
|
|
|
do_compile_append() {
|
|
if [ "${LIBVIRT_PYTHON_ENABLE}" = "1" ]; then
|
|
# we need the python bindings to look into our source dir, not
|
|
# the syroot staged pkgconfig entries. So we clear the sysroot
|
|
# for just this portion.
|
|
export PKG_CONFIG_SYSROOT_DIR=
|
|
cd ${WORKDIR}/${BPN}-python-${PV} && \
|
|
${STAGING_BINDIR_NATIVE}/python3-native/python3 setup.py build
|
|
fi
|
|
}
|
|
|
|
do_install_append() {
|
|
if [ "${LIBVIRT_PYTHON_ENABLE}" = "1" ]; then
|
|
# we need the python bindings to look into our source dir, not
|
|
# the syroot staged pkgconfig entries. So we clear the sysroot
|
|
# for just this portion.
|
|
export PKG_CONFIG_SYSROOT_DIR=
|
|
cd ${WORKDIR}/${BPN}-python-${PV} && \
|
|
${STAGING_BINDIR_NATIVE}/python3-native/python3 setup.py install \
|
|
--install-lib=${D}/${PYTHON_SITEPACKAGES_DIR} ${LIBVIRT_INSTALL_ARGS}
|
|
fi
|
|
}
|