mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
117425a745
Integrating the following 2.7 release commits: cf8615de Remove empty Content-Type header 48eeac88 docs: add redirect for old URL e2f006ac S3 Driver: added comment for missing KeyCount workaround 0a1e4a57 Fix s3 driver for supporting ceph radosgw afa91463 Bugfix: Make ipfilteredby not required fad36ed1 Add reference.ParseDockerRef utility function f999f540 Fixing broken table c636ed78 Fix cloudfront documentation formatting 5883e2d9 Fix vndr and check a3c027e6 Adding deprecated schema instructions Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
72 lines
2.4 KiB
BlitzBasic
72 lines
2.4 KiB
BlitzBasic
HOMEPAGE = "http://github.com/docker/distribution"
|
|
SUMMARY = "The Docker toolset to pack, ship, store, and deliver content"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=d2794c0df5b907fdace235a619d80314"
|
|
|
|
SRCREV_distribution="d7362d7e3a706f3200be70369544094fea3e5b7c"
|
|
SRC_URI = "git://github.com/docker/distribution.git;branch=release/2.7;name=distribution;destsuffix=git/src/github.com/docker/distribution \
|
|
file://docker-registry.service \
|
|
file://0001-build-use-to-use-cross-go-compiler.patch \
|
|
"
|
|
|
|
PACKAGES =+ "docker-registry"
|
|
|
|
PV = "v2.7.1"
|
|
S = "${WORKDIR}/git/src/github.com/docker/distribution"
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
inherit goarch
|
|
inherit go
|
|
|
|
# This disables seccomp and apparmor, which are on by default in the
|
|
# go package.
|
|
EXTRA_OEMAKE="BUILDTAGS=''"
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
export GOPATH="${WORKDIR}/git/"
|
|
export GOROOT="${STAGING_LIBDIR_NATIVE}/${TARGET_SYS}/go"
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CFLAGS=""
|
|
export LDFLAGS=""
|
|
export CGO_CFLAGS="${BUILDSDK_CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export GO_GCFLAGS=""
|
|
export CGO_LDFLAGS="${BUILDSDK_LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
|
|
cd ${S}
|
|
|
|
oe_runmake binaries
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/${sbindir}
|
|
install ${S}/bin/registry ${D}/${sbindir}
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 644 ${WORKDIR}/docker-registry.service ${D}/${systemd_unitdir}/system
|
|
fi
|
|
|
|
install -d ${D}/${sysconfdir}/docker-distribution/registry/
|
|
install ${S}/cmd/registry/config-example.yml ${D}/${sysconfdir}/docker-distribution/registry/config.yml
|
|
|
|
# storage for the registry containers
|
|
install -d ${D}/${localstatedir}/lib/registry/
|
|
}
|
|
|
|
INSANE_SKIP_${PN} += "ldflags already-stripped"
|
|
INSANE_SKIP_${MLPREFIX}docker-registry += "ldflags already-stripped textrel"
|
|
|
|
FILES_docker-registry = "${sbindir}/*"
|
|
FILES_docker-registry += "${systemd_unitdir}/system/docker-registry.service"
|
|
FILES_docker-registry += "${sysconfdir}/docker-distribution/*"
|
|
FILES_docker-registry += "${localstatedir}/lib/registry/"
|
|
|
|
SYSTEMD_SERVICE_docker-registry = "${@bb.utils.contains('DISTRO_FEATURES','systemd','docker-registry.service','',d)}"
|
|
SYSTEMD_AUTO_ENABLE_docker-registry = "enable"
|
|
|
|
RDEPENDS_${PN}-ptest_remove = "${PN}"
|