mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 20:59:41 +02:00
1db447e785
- d6f842b0 test: e2e test reliability improvements (#10950) - 4fbbf201 build(deps): upgrade to compose-go v1.18.3 (#10947) - 935d72f4 added the dot at the end of the sentence - 41682acc add support for attributes exposed by `docker ps` - 1054792b align docker compose ps with docker CLI to support --format - 19f66918 watch: only allow a single instance per-project - 186744e0 ci: bump golangci-lint to v1.54.2 - bc9d696f Merge pull request #10922 from thaJeztah/replace_dockerignore - 6204fb1c logs: fix for missing output on container exit (#10925) - 5d732010 replace dockerfile/dockerignore with patternmatcher/ignorefile - 2006f3fe go.mod: github.com/moby/patternmatcher v0.6.0 - 192718c0 go.mod: remove some outdated comments - c79f67fe otel: add `include` to project up span - 3b294bfd build(deps): bump github.com/compose-spec/compose-go from 1.18.1 to 1.18.2 (#10915) - dd34f7a2 include: add experimental support for Git resources (#10811) - caad7271 up: handle various attach use cases better - 792afb8d build: use correct values for proxy variables (#10908) - 150449bb warn user secret uid/gid/mode is not supported Signed-off-by: Jose Quaresma <jose.quaresma@foundries.io> Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
81 lines
2.1 KiB
BlitzBasic
81 lines
2.1 KiB
BlitzBasic
HOMEPAGE = "https://github.com/docker/compose"
|
|
SUMMARY = "Multi-container orchestration for Docker"
|
|
DESCRIPTION = "Docker compose v2"
|
|
|
|
DEPENDS = " \
|
|
go-md2man \
|
|
rsync-native \
|
|
"
|
|
|
|
# Specify the first two important SRCREVs as the format
|
|
SRCREV_FORMAT="compose_survey"
|
|
SRCREV_compose = "d6f842b042d2f2926901305336527b3eaadf067a"
|
|
|
|
SRC_URI = "git://github.com/docker/compose;name=compose;branch=main;protocol=https"
|
|
|
|
include src_uri.inc
|
|
|
|
# patches and config
|
|
SRC_URI += "file://modules.txt"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://src/import/LICENSE;md5=175792518e4ac015ab6696d16c4f607e"
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
PV = "v2.21.0"
|
|
|
|
COMPOSE_PKG = "github.com/docker/compose/v2"
|
|
|
|
inherit go goarch
|
|
inherit pkgconfig
|
|
|
|
COMPATIBLE_HOST = "^(?!mips).*"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
PACKAGECONFIG ?= ""
|
|
|
|
include relocation.inc
|
|
|
|
GOBUILDFLAGS:append = " -mod=vendor"
|
|
do_compile() {
|
|
cd ${S}/src/import
|
|
|
|
export GOPATH="$GOPATH:${S}/src/import/.gopath"
|
|
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export GOARCH=${TARGET_GOARCH}
|
|
export CGO_ENABLED="1"
|
|
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
|
|
# our copied .go files are to be used for the build
|
|
ln -sf vendor.copy vendor
|
|
# inform go that we know what we are doing
|
|
cp ${WORKDIR}/modules.txt vendor/
|
|
|
|
GO_LDFLAGS="-s -w -X internal.Version=${PV} -X ${COMPOSE_PKG}/internal.Version=${PV}"
|
|
GO_BUILDTAGS=""
|
|
mkdir -p ./bin
|
|
${GO} build ${GOBUILDFLAGS} -tags "$GO_BUILDTAGS" -ldflags "$GO_LDFLAGS" -o ./bin/docker-compose ./cmd
|
|
}
|
|
|
|
do_install() {
|
|
#install -d "${D}${BIN_PREFIX}/bin"
|
|
#install -m 755 "${S}/src/import/bin/docker-compose" "${D}${BIN_PREFIX}/bin"
|
|
|
|
# commonly installed to: /usr/lib/docker/cli-plugins/
|
|
install -d "${D}${nonarch_libdir}/docker/cli-plugins/"
|
|
install -m 755 "${S}/src/import/bin/docker-compose" "${D}${nonarch_libdir}/docker/cli-plugins/"
|
|
|
|
}
|
|
|
|
RDEPENDS:${PN} += " docker"
|
|
|
|
FILES:${PN} += " ${nonarch_libdir}/docker/cli-plugins/"
|
|
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
INSANE_SKIP:${PN} += "ldflags already-stripped"
|