mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 20:59:41 +02:00
28fda6d848
The src/import/build/root/Makefile.generated_files are called several times during the build, so the following target which installs go2make will also run several times: $(META_DIR)/$(GO_PKGDEPS_FILE): FORCE It runs automatically when the Makefile is called because of: sinclude $(META_DIR)/$(GO_PKGDEPS_FILE) So there is a race issue of go2make when parallel build: hack/run-in-gopath.sh: line 34: build/tmp-glibc/work/corei7-64-wrs-linux/kubernetes/1.18.8-r0/git/src/import/_output/local/go/bin/go2make: No suc h file or directory Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
115 lines
4.3 KiB
BlitzBasic
115 lines
4.3 KiB
BlitzBasic
HOMEPAGE = "git://github.com/kubernetes/kubernetes"
|
|
SUMMARY = "Production-Grade Container Scheduling and Management"
|
|
DESCRIPTION = "Kubernetes is an open source system for managing containerized \
|
|
applications across multiple hosts, providing basic mechanisms for deployment, \
|
|
maintenance, and scaling of applications. \
|
|
"
|
|
|
|
PV = "v1.19.0-rc.3+git${SRCREV_kubernetes}"
|
|
SRCREV_kubernetes = "bdc575e10c35a3e65a1c02bceea432832b7e4f4f"
|
|
SRCREV_kubernetes-release = "e7fbf5b8b7e87ed1848cf3a0129f7a7dff2aa4ed"
|
|
|
|
SRC_URI = "git://github.com/kubernetes/kubernetes.git;branch=release-1.19;name=kubernetes \
|
|
git://github.com/kubernetes/release;branch=master;name=kubernetes-release;destsuffix=git/release \
|
|
file://0001-hack-lib-golang.sh-use-CC-from-environment.patch \
|
|
file://0001-cross-don-t-build-tests-by-default.patch \
|
|
file://0001-generate-bindata-unset-GOBIN.patch \
|
|
file://0001-build-golang.sh-convert-remaining-go-calls-to-use.patch \
|
|
file://0001-Makefile.generated_files-Fix-race-issue-for-installi.patch \
|
|
"
|
|
|
|
DEPENDS += "rsync-native \
|
|
coreutils-native \
|
|
"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://src/import/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
inherit systemd
|
|
inherit go
|
|
inherit goarch
|
|
|
|
COMPATIBLE_HOST = '(x86_64.*|arm.*|aarch64.*)-linux'
|
|
|
|
do_compile() {
|
|
# link fixups for compilation
|
|
rm -f ${S}/src/import/vendor/src
|
|
ln -sf ./ ${S}/src/import/vendor/src
|
|
|
|
export GOPATH="${S}/src/import/.gopath:${S}/src/import/vendor:${STAGING_DIR_TARGET}/${prefix}/local/go"
|
|
cd ${S}/src/import
|
|
|
|
# Build the host tools first, using the host compiler
|
|
export GOARCH="${BUILD_GOARCH}"
|
|
# Pass the needed cflags/ldflags so that cgo can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CFLAGS="${BUILD_CFLAGS}"
|
|
export LDFLAGS="${BUILD_LDFLAGS}"
|
|
export CGO_CFLAGS="${BUILD_CFLAGS}"
|
|
export CGO_LDFLAGS="${BUILD_LDFLAGS}"
|
|
export CC="${BUILD_CC}"
|
|
export LD="${BUILD_LD}"
|
|
|
|
make generated_files GO="go" KUBE_BUILD_PLATFORMS="${HOST_GOOS}/${BUILD_GOARCH}"
|
|
|
|
# Build the target binaries
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
# Pass the needed cflags/ldflags so that cgo can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CFLAGS=""
|
|
export LDFLAGS=""
|
|
export CC="${CC}"
|
|
export LD="${LD}"
|
|
export GOBIN=""
|
|
|
|
# to limit what is built, use 'WHAT', i.e. make WHAT=cmd/kubelet
|
|
make cross CGO_FLAGS=${CGO_FLAGS} GO=${GO} KUBE_BUILD_PLATFORMS=${GOOS}/${GOARCH} GOLDFLAGS=""
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${bindir}
|
|
install -d ${D}${systemd_unitdir}/system/
|
|
install -d ${D}${systemd_unitdir}/system/kubelet.service.d/
|
|
|
|
install -d ${D}${sysconfdir}/kubernetes/manifests/
|
|
|
|
install -m 755 -D ${S}/src/import/_output/local/bin/${TARGET_GOOS}/${TARGET_GOARCH}/* ${D}/${bindir}
|
|
|
|
install -m 0644 ${WORKDIR}/git/release/cmd/kubepkg/templates/latest/deb/kubelet/lib/systemd/system/kubelet.service ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${WORKDIR}/git/release/cmd/kubepkg/templates/latest/deb/kubeadm/10-kubeadm.conf ${D}${systemd_unitdir}/system/kubelet.service.d/
|
|
}
|
|
|
|
PACKAGES =+ "kubeadm kubectl kubelet kube-proxy ${PN}-misc"
|
|
|
|
ALLOW_EMPTY_${PN} = "1"
|
|
INSANE_SKIP_${PN} += "ldflags already-stripped"
|
|
INSANE_SKIP_${PN}-misc += "ldflags already-stripped"
|
|
|
|
# Note: we are explicitly *not* adding docker to the rdepends, since we allow
|
|
# backends like cri-o to be used.
|
|
RDEPENDS_${PN} += "kubeadm \
|
|
kubectl \
|
|
kubelet \
|
|
cni"
|
|
|
|
RDEPENDS_kubeadm = "kubelet kubectl"
|
|
FILES_kubeadm = "${bindir}/kubeadm ${systemd_unitdir}/system/kubelet.service.d/*"
|
|
|
|
RDEPENDS_kubelet = "iptables socat util-linux ethtool iproute2 ebtables iproute2-tc"
|
|
FILES_kubelet = "${bindir}/kubelet ${systemd_unitdir}/system/kubelet.service ${sysconfdir}/kubernetes/manifests/"
|
|
|
|
SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','kubelet','',d)}"
|
|
SYSTEMD_SERVICE_kubelet = "${@bb.utils.contains('DISTRO_FEATURES','systemd','kubelet.service','',d)}"
|
|
SYSTEMD_AUTO_ENABLE_kubelet = "enable"
|
|
|
|
FILES_kubectl = "${bindir}/kubectl"
|
|
FILES_kube-proxy = "${bindir}/kube-proxy"
|
|
FILES_${PN}-misc = "${bindir}"
|
|
|
|
|
|
deltask compile_ptest_base
|