mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
351644d9bc
Bumping skopeo to version v1.18.0-67-ge8d9f916, which comprises the following commits:
da1bf9f7 chore(deps): update dependency containers/automation_images to v20250324
7983f20a Remove obsolete build tag syntax
8d000f45 Use the new maps.Keys and slices.Sorted
1f49b2c0 Use slices.Backward
a31470d7 proxy: Add GetLayerInfoPiped
ec219604 Update github.com/hashicorp/go-multierror
1a38d976 Update github.com/dsnet/compress
49569bcf Complete paths for some transports
e7e09255 Don't complete a space after '<transport>:'
9c0f31dc In (skopeo inspect), validate the manifest against a digest reference
9fda7e73 In (skopeo layers), validate the blob against the expected digest
a0799484 Always close the blob we are reading from a registry
a5182876 fix(deps): update module golang.org/x/term to v0.30.0
b8637922 chore(deps): update dependency golangci/golangci-lint to v1.64.8
56ccf09c ROADMAP: new file
03fa889d chore(deps): update module golang.org/x/net to v0.36.0 [security]
15132e6c Update to Go 1.23
4080a631 fix(deps): update module github.com/containers/common to v0.62.2
cc743c3c chore(deps): update dependency golangci/golangci-lint to v1.64.7
91c6aa61 fix(deps): update module github.com/containers/image/v5 to v5.34.2
d00ea33d fix(deps): update module github.com/containers/storage to v1.57.2
7bd0dc21 .github: remove cirrus rerun action
547141ce fix(deps): update module github.com/opencontainers/image-spec to v1.1.1
a185498c chore(deps): update dependency golangci/golangci-lint to v1.64.6
fad5a31a chore(deps): update module github.com/go-jose/go-jose/v4 to v4.0.5 [security]
5744b9b4 chore(deps): update module github.com/go-jose/go-jose/v3 to v3.0.4 [security]
934ea727 fix(deps): update module github.com/containers/common to v0.62.1
8a44fe6c fix(deps): update module github.com/containers/image/v5 to v5.34.1
c7aaed73 Update for cobra API change
9d73060a fix(deps): update module github.com/spf13/cobra to v1.9.1
5c968d67 chore(deps): update dependency golangci/golangci-lint to v1.64.5
841a1b61 chore(deps): update dependency golangci/golangci-lint to v1.64.4
8c2eff1d chore(deps): update dependency golangci/golangci-lint to v1.64.3
f88186e6 [skip-ci] Packit/TMT: Run system tests
ff462b3d PR Labels: apply release label to release- branch PRs
8c20592d chore(deps): update dependency golangci/golangci-lint to v1.64.2
20746ae2 Bump Skopeo to v1.19.0-dev
64361bde Bump Skopeo to v1.18.0
bd1ac466 Switch to the CNCF Code of Conduct
59ec5547 fix(deps): update module golang.org/x/term to v0.29.0
04d65888 fix(deps): update module github.com/containers/common to v0.62.0
137a912c chore(deps): update dependency containers/automation_images to v20250131
52895bc6 fix(deps): update module github.com/spf13/pflag to v1.0.6
b78a4159 fix(deps): update module github.com/containers/image/v5 to v5.34.0
5eba0614 RPM: include check section to silence rpmlint
9764c99d RPM: cleanup gobuild macro for CentOS Stream
a81cb65f fix(deps): update module github.com/containers/storage to v1.57.1
85fa4dff fix(deps): update module github.com/containers/storage to v1.57.0
ed0efc69 feat: Add `--retry-delay` Option
ab53f644 fix(deps): update module github.com/containers/common to v0.61.1
653db366 fix(deps): update module github.com/containers/image/v5 to v5.33.1
6483de48 fix(deps): update module github.com/containers/storage to v1.56.1
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
92 lines
2.3 KiB
BlitzBasic
92 lines
2.3 KiB
BlitzBasic
HOMEPAGE = "https://github.com/containers/skopeo"
|
|
SUMMARY = "Work with remote images registries - retrieving information, images, signing content"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=7e611105d3e369954840a6668c438584"
|
|
|
|
DEPENDS = " \
|
|
gpgme \
|
|
libdevmapper \
|
|
lvm2 \
|
|
btrfs-tools \
|
|
glib-2.0 \
|
|
"
|
|
|
|
inherit go
|
|
|
|
COMPATIBLE_HOST = "^(?!mips).*"
|
|
|
|
RDEPENDS:${PN} = " \
|
|
gpgme \
|
|
libgpg-error \
|
|
libassuan \
|
|
"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/containers/skopeo;branch=main;protocol=https;destsuffix=git/src/github.com/containers/skopeo \
|
|
file://0001-makefile-add-GOBUILDFLAGS-to-go-build-call.patch \
|
|
"
|
|
|
|
SRCREV = "e8d9f916e04364c128a939535889dc2da74162b5"
|
|
PV = "v1.18.0+git"
|
|
GO_IMPORT = "import"
|
|
|
|
S = "${WORKDIR}/git/src/github.com/containers/skopeo"
|
|
|
|
inherit goarch
|
|
inherit pkgconfig
|
|
|
|
inherit container-host
|
|
|
|
# https://bugzilla.redhat.com/show_bug.cgi?id=CVE-2019-10214
|
|
# https://github.com/containers/image/issues/654
|
|
CVE_STATUS[CVE-2019-10214] = "fixed-version: This CVE was fixed in the container image go library skopeo is using."
|
|
|
|
# This disables seccomp and apparmor, which are on by default in the
|
|
# go package.
|
|
EXTRA_OEMAKE="BUILDTAGS=''"
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
|
|
export GOPATH="${S}/src/import/.gopath:${S}/src/import/vendor:${STAGING_DIR_TARGET}/${prefix}/local/go:${WORKDIR}/git/"
|
|
cd ${S}
|
|
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CFLAGS=""
|
|
export LDFLAGS=""
|
|
export CGO_CFLAGS="${TARGET_CFLAGS}"
|
|
export CGO_LDFLAGS="${TARGET_LDFLAGS}"
|
|
|
|
export GO111MODULE=off
|
|
export GOBUILDFLAGS="-trimpath"
|
|
export EXTRA_LDFLAGS="-s -w"
|
|
|
|
oe_runmake bin/skopeo
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/${sbindir}
|
|
install -d ${D}/${sysconfdir}/containers
|
|
|
|
install ${S}/bin/skopeo ${D}/${sbindir}/
|
|
}
|
|
|
|
do_install:append:class-native() {
|
|
create_cmdline_wrapper ${D}/${sbindir}/skopeo \
|
|
--policy ${sysconfdir}/containers/policy.json
|
|
|
|
create_wrapper ${D}/${sbindir}/skopeo.real \
|
|
LD_LIBRARY_PATH=${STAGING_LIBDIR_NATIVE}
|
|
}
|
|
|
|
do_install:append:class-nativesdk() {
|
|
create_cmdline_wrapper ${D}/${sbindir}/skopeo \
|
|
--policy ${sysconfdir}/containers/policy.json
|
|
}
|
|
|
|
INSANE_SKIP:${PN} += "ldflags already-stripped"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|