mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2026-01-27 10:41:26 +01:00
5302350d7a
Bumping buildah to version v1.41.5-1-g0e4301a18, which comprises the following commits:
7d95c695c Tag v1.41.5
b7b5a915c tests/run.bats: "run masks" test: accept "unreadable" masked directories
913046ac2 Run: create parent directories of mount targets with mode 0755
4094f92e3 [release-1.41] Bump to Buildah v1.41.4
4acf2a549 [release-1.41] c/common to v0.64.2, ulikunitz/xv v0.5.12, docker/docker v28.3.3
b60c59c79 [release-1.41] Bump Buildah to v1.41.3
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
63 lines
1.9 KiB
BlitzBasic
63 lines
1.9 KiB
BlitzBasic
HOMEPAGE = "https://buildah.io"
|
|
SUMMARY = "A tool that facilitates building OCI container images."
|
|
DESCRIPTION = "A tool that facilitates building OCI container images."
|
|
|
|
# Apache-2.0 for containerd
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://src/github.com/containers/buildah/LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
|
|
|
|
BUILDAH_VERSION = "1.41.5"
|
|
|
|
PV = "${BUILDAH_VERSION}"
|
|
|
|
inherit go
|
|
inherit goarch
|
|
inherit pkgconfig
|
|
|
|
# Rdepends on podman which needs seccomp and ipv6
|
|
inherit features_check
|
|
REQUIRED_DISTRO_FEATURES = "seccomp ipv6"
|
|
|
|
COMPATIBLE_HOST = "^(?!mips).*"
|
|
|
|
GO_IMPORT = "github.com/containers/buildah"
|
|
GO_INSTALL = "${GO_IMPORT}"
|
|
GO_WORKDIR = "${GO_INSTALL}"
|
|
GOBUILDFLAGS += "-mod vendor"
|
|
|
|
SRCREV = "0e4301a18e6a386a073f6f683f52f5def81231ab"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/containers/buildah;branch=release-1.41;name=buildah;protocol=https;destsuffix=${GO_SRCURI_DESTSUFFIX} \
|
|
"
|
|
|
|
DEPENDS = "libdevmapper btrfs-tools gpgme"
|
|
RDEPENDS:${PN} = "cgroup-lite fuse-overlayfs libdevmapper podman"
|
|
RDEPENDS:${PN}-dev = "bash perl"
|
|
|
|
do_compile:prepend() {
|
|
cd ${S}/src/github.com/containers/buildah
|
|
}
|
|
|
|
go_do_compile() {
|
|
export TMPDIR="${GOTMPDIR}"
|
|
export AS='${CC} -c'
|
|
if [ -n "${GO_INSTALL}" ]; then
|
|
${GO} install ${GOBUILDFLAGS} ./cmd/buildah
|
|
${GO} install ${GOBUILDFLAGS} ./tests/imgtype/imgtype.go
|
|
${GO} install ${GOBUILDFLAGS} ./tests/copy/copy.go
|
|
fi
|
|
|
|
# x86 statically linked executable that we don't need
|
|
rm -f ${S}/src/github.com/containers/buildah/internal/mkcw/embed/entrypoint
|
|
}
|
|
|
|
do_install:append() {
|
|
dest_dir=${D}/${sysconfdir}/containers
|
|
mkdir -p ${dest_dir}
|
|
install -m 666 ${S}/src/github.com/containers/buildah/docs/samples/registries.conf ${dest_dir}/buildah.registries.conf.sample
|
|
install -m 666 ${S}/src/github.com/containers/buildah/tests/policy.json ${dest_dir}/buildah.policy.json.sample
|
|
}
|
|
|
|
INSANE_SKIP:${PN} = "already-stripped"
|