mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
55de27c51a
Bumping containerd to version v1.7.1-4-g835383b17, which comprises the following commits:
6a5e54c15 Get CDI devices from CRI Config.CDIDevices field
9e60300ea snapshots/testsuite: Rename: fix fuse-overlayfs incompatibility
7b288e2d7 Update ttrpc to v1.2.2
27a0d957b Prepare release notes for v1.7.1
0e0532eb2 bump typeurl to v2.1.1
35e86f96c [transfer] avoid setting limiters when max is 0
f7233811f Update transfer configuration
4510eac00 Fix image pulling with Transfer service
aaa65e8c1 Update hcsshim tag to v0.10.0-rc.8
95ef67e19 Fix umarshal metrics for CRI server
3ef5b689a runtime/shim: fix the nil checkpoint options
021bba28b update go to go1.20.4, go1.19.9
6b3ae0129 Remove entry for container from container store on error
c0e128624 skip TestContainerStartWithAbsRuntimePath if the runtime is v1
aa3c63c15 integration: add container start test using abs runtime path
d2d9eedb1 WithRuntimePath uses the TaskInfo.RuntimePath field
fae4b6223 update runc binary to v1.1.7
571715a9d cri: Vendor v0.27.1
a6d336c1f Fix argsEscaped tests
1bbf98e53 oci: partially restore comment on read-only mounts for uid/gid uses
8f6e86fec go.mod: add comment explaining go-fuzz-headers replace rule
1ece0cb50 go.mod: remove replace for github.com/opencontainers/runtime-tools
e9f962187 go.mod: integration: use non-pre-release of containerd
84393b005 go.mod: integration: move indirect dependencies to the right group
dec2595af update runc binary to v1.1.6
7de8629be cri: Throw an error if idmap mounts is requested
75ac7e0d8 cri: Vendor v0.27.0-beta.0 for mounts uid/gid mappings
54d12b872 oci: Use WithReadonlyTempMount when adding users/groups
624327651 update go to go1.20.3, go1.19.8
1d6641b7c export: add test for WithSkipDockerManifest
0e0d84f6b archive: consistently respect value of WithSkipDockerManifest
9b4935d86 Update sbserver to add noexec nodev and nosuid to /etc/resolv.conf mount bind.
5e953cfa6 Test to ensure nosuid,nodev,noexec are set on /etc/reolv.conf mount.
0aad93f08 Add noexec nodev and nosuid to sandbox /etc/resolv.conf mount bind.
1a64f1b43 ctr/tasks: fix unmarshal the task metrics for cgroups v1
17c52a26d Keep linux mounts for linux sandboxes on Windows/Darwin
d81fc15af update runc binary to v1.1.5
755efbe64 go.mod: github.com/opencontainers/runc v1.1.5
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
104 lines
3.6 KiB
BlitzBasic
104 lines
3.6 KiB
BlitzBasic
HOMEPAGE = "https://github.com/docker/containerd"
|
|
SUMMARY = "containerd is a daemon to control runC"
|
|
DESCRIPTION = "containerd is a daemon to control runC, built for performance and density. \
|
|
containerd leverages runC's advanced features such as seccomp and user namespace \
|
|
support as well as checkpoint and restore for cloning and live migration of containers."
|
|
|
|
|
|
SRCREV = "835383b17f302b1c855ec9dd378bd045c073e001"
|
|
SRC_URI = "git://github.com/containerd/containerd;branch=release/1.7;protocol=https;destsuffix=git/src/github.com/containerd/containerd \
|
|
file://0001-Makefile-allow-GO_BUILD_FLAGS-to-be-externally-speci.patch \
|
|
file://0001-build-don-t-use-gcflags-to-define-trimpath.patch \
|
|
"
|
|
|
|
# Apache-2.0 for containerd
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1269f40c0d099c21a871163984590d89"
|
|
|
|
CONTAINERD_VERSION = "v1.7.1"
|
|
CVE_VERSION = "v1.7.1"
|
|
|
|
# EXTRA_OEMAKE += "GODEBUG=1"
|
|
|
|
PROVIDES += "virtual/containerd"
|
|
RPROVIDES:${PN} = "virtual-containerd"
|
|
|
|
S = "${WORKDIR}/git/src/github.com/containerd/containerd"
|
|
|
|
PV = "${CONTAINERD_VERSION}+git${SRCPV}"
|
|
|
|
inherit go
|
|
inherit goarch
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
CONTAINERD_PKG="github.com/containerd/containerd"
|
|
|
|
INSANE_SKIP:${PN} += "ldflags"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
|
|
export GOPATH="${S}/src/import/.gopath:${S}/src/import/vendor:${STAGING_DIR_TARGET}/${prefix}/local/go:${WORKDIR}/git/"
|
|
export GOROOT="${STAGING_DIR_NATIVE}/${nonarch_libdir}/${HOST_SYS}/go"
|
|
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export BUILDTAGS="no_btrfs static_build netgo"
|
|
export CFLAGS="${CFLAGS}"
|
|
export LDFLAGS="${LDFLAGS}"
|
|
export SHIM_CGO_ENABLED="${CGO_ENABLED}"
|
|
# fixes:
|
|
# cannot find package runtime/cgo (using -importcfg)
|
|
# ... recipe-sysroot-native/usr/lib/aarch64-poky-linux/go/pkg/tool/linux_amd64/link:
|
|
# cannot open file : open : no such file or directory
|
|
export GO_BUILD_FLAGS="-trimpath -a -pkgdir dontusecurrentpkgs"
|
|
export GO111MODULE=off
|
|
|
|
cd ${S}
|
|
|
|
oe_runmake binaries
|
|
}
|
|
|
|
inherit systemd
|
|
SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${PN}','',d)}"
|
|
SYSTEMD_SERVICE:${PN} = "${@bb.utils.contains('DISTRO_FEATURES','systemd','containerd.service','',d)}"
|
|
|
|
do_install() {
|
|
mkdir -p ${D}/${bindir}
|
|
|
|
cp ${S}/bin/containerd ${D}/${bindir}/containerd
|
|
cp ${S}/bin/containerd-shim ${D}/${bindir}/containerd-shim
|
|
cp ${S}/bin/containerd-shim-runc-v1 ${D}/${bindir}/containerd-shim-runc-v1
|
|
cp ${S}/bin/containerd-shim-runc-v2 ${D}/${bindir}/containerd-shim-runc-v2
|
|
cp ${S}/bin/ctr ${D}/${bindir}/containerd-ctr
|
|
|
|
ln -sf containerd ${D}/${bindir}/docker-containerd
|
|
ln -sf containerd-shim ${D}/${bindir}/docker-containerd-shim
|
|
ln -sf containerd-ctr ${D}/${bindir}/docker-containerd-ctr
|
|
|
|
ln -sf containerd-ctr ${D}/${bindir}/ctr
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 644 ${S}/containerd.service ${D}/${systemd_unitdir}/system
|
|
# adjust from /usr/local/bin to /usr/bin/
|
|
sed -e "s:/usr/local/bin/containerd:${bindir}/containerd:g" -i ${D}/${systemd_unitdir}/system/containerd.service
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += "${systemd_system_unitdir}/*"
|
|
|
|
INSANE_SKIP:${PN} += "ldflags already-stripped"
|
|
|
|
COMPATIBLE_HOST = "^(?!(qemu)?mips).*"
|
|
|
|
RDEPENDS:${BPN} += " ${VIRTUAL-RUNTIME_container_runtime}"
|
|
|
|
CVE_PRODUCT = "containerd"
|