mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
7ea990b79d
Bumping crun to version 1.17-5-g4b75c7c, which comprises the following commits:
4ea62f2 Disable criu support on riscv64
969fd2e Packit: Create missing path components in files_to_sync
000fa0d NEWS: tag 1.17
e3b5a26 Packit: Reuse Fedora targets wherever possible
556b808 Packit: separate out ELN build jobs
a5320ae Add debug logs for container creation
228ad7c container: remove manual dup operation
13ea475 libocispec: sync from upstream
3dbf152 error: do not write error twice to stderr
5e35dfe libcrun: vanity, color debug messages
2c4db99 linux: ignore EPIPE for hooks
7fcede6 RPM/Packit: Fix wasm conditionals, cleanup rpm spec, update packit config
0f556b7 build: force install symlinks
23d5e49 Fix warning around unused result on chdir("/")
6bf9e7c Report executable not found errors after tty has been setup
a295e70 Only log to stderr if `--log` is not provided
fb593fc fix getpwuid_r error handling
d29fdae tests: bump containerd version
f36c216 tests: bump ubuntu version
d065a5a Revert "Add `--log-stderr` option"
dc31069 src/libcrun: fix handling of device paths with trailing slashes
ab64a5c linux: fix recvfrom error handling
a32d433 Fix `additional_gids_size` on `process_user_dup`
b98e0dd Add `--log-stderr` option
544fe3f Allow passing an ID to journald log driver
6d92b28 Log only after crun context has been setup
29259e4 Add log options documentation
f72483a Fix double-free in crun exec
e4b4a21 src/libcrun: fix error handling in libcrun_kill_linux
83c1355 src/libcrun: improve error handling for the mnt namespace restoration
6fb1f08 src/libcrun: added custom error message for ESRCH case
9f06d3c Add autoPatchelfHook to static build
19b9893 Add `--log-level` option
fd7f50a tests: fix wasmedge build
0380369 Remove libcrun_setup_terminal_ptmx
1edf6d0 src/libcrun: ensure DefaultDependencies respects CRI-O annotation
42b0b99 configure.ac: fix condition for wasm detection
afa829c NEWS: tag 1.16.1
c6ecb3b linux: attempt to make rootfs private too
109f1e9 container: fix comment
f23aaa1 linux: fix error message
72b4eea Inherit user from original process on exec
cf1ec33 cgroup-utils: check for open error
a958fcd cgroup-systemd: fix comment
7112df4 cgroup: remove redundant check
3bcd26a Use write_file_at_with_flags in write_file_with_flags
2dc1598 NEWS: tag 1.16
bfa0640 Add more O_PATH flags
0613ec5 cgroup-systemd: check for sd_bus_message_append error
fcfac99 Fix sd-bus error handling for cpu quota and period props update.
6682432 linux: make_parent_mount_private uses fds
5943335 container: use relative path for rootfs if possible
27d7dd3 README: update podman demo
f916acf Enable systemd in s390x builds
e6eab76 wasmedge: access container environment variables for WasmEdge configuration
Bumping libocispec to latest, which comprises the following commits:
4b8feed common: make sizeof the last argument for calloc
2ba727a sources: silence compiler warning
3ec73ba generate: generate clone operations for deep-copy
d371222 ocispec: fix style
2236d50 github: test with the embedded yajl library
bed19ad configure.ac: --enable-embedded-yajl skips check for yajl
b633f89 Makefile.am: distribute the src/yajl symlink
Bumping image-spec to version v1.1.0-35-gda92727, which comprises the following commits:
716f83b Implementations should support zstd
7327da4 Add deprecation notices to nondistributable layers
1d3daab Update linter and Go releases
16101e2 Remove misleading "must" in `ref.name` requirements
65dea7a Remove IRC link
a977bd3 Remove validation warnings to stdout
4bbdd7f Switch jsonschema validation libraries
89fee07 MAINTAINERS: move jonboulle to EMERITUS
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
51 lines
2.1 KiB
BlitzBasic
51 lines
2.1 KiB
BlitzBasic
DESCRIPTION = "A fast and low-memory footprint OCI Container Runtime fully written in C."
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
PRIORITY = "optional"
|
|
|
|
SRCREV_crun = "4b75c7cb574d642481c9346eb3d54e91c33ebaf2"
|
|
SRCREV_libocispec = "68211ccc41201c45ad276b04c7f67d61e80b1f7a"
|
|
SRCREV_ispec = "da92727e9c8761ec087890466b8756b755aefd37"
|
|
SRCREV_rspec = "2d3f72ecad9e97c898e1eb04b899a51241f1cabd"
|
|
SRCREV_yajl = "f344d21280c3e4094919fd318bc5ce75da91fc06"
|
|
|
|
SRCREV_FORMAT = "crun_rspec"
|
|
SRC_URI = "git://github.com/containers/crun.git;branch=main;name=crun;protocol=https \
|
|
git://github.com/containers/libocispec.git;branch=main;name=libocispec;destsuffix=git/libocispec;protocol=https \
|
|
git://github.com/opencontainers/runtime-spec.git;branch=main;name=rspec;destsuffix=git/libocispec/runtime-spec;protocol=https \
|
|
git://github.com/opencontainers/image-spec.git;branch=main;name=ispec;destsuffix=git/libocispec/image-spec;protocol=https \
|
|
git://github.com/containers/yajl.git;branch=main;name=yajl;destsuffix=git/libocispec/yajl;protocol=https \
|
|
"
|
|
|
|
PV = "v1.17+git${SRCREV_crun}"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig
|
|
|
|
PACKAGECONFIG ??= " \
|
|
caps external-yajl man \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'seccomp', 'seccomp', '', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[caps] = "--enable-caps,--disable-caps,libcap"
|
|
PACKAGECONFIG[external-yajl] = "--disable-embedded-yajl,--enable-embedded-yajl,yajl"
|
|
# whether to regenerate manpages that are already present in the repo
|
|
PACKAGECONFIG[man] = ",,go-md2man-native"
|
|
PACKAGECONFIG[seccomp] = "--enable-seccomp,--disable-seccomp,libseccomp"
|
|
PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,systemd"
|
|
|
|
DEPENDS = "m4-native"
|
|
DEPENDS:append:libc-musl = " argp-standalone"
|
|
|
|
do_configure:prepend () {
|
|
# extracted from autogen.sh in crun source. This avoids
|
|
# git submodule fetching.
|
|
mkdir -p m4
|
|
autoreconf -fi
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
}
|