mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
61cec3e210
Rather than waiting for release tarballs for the main libvirt release, we can just use the git repository directory and avoid patch backporting for CVEs, etc. As part of this change, we adjust to git, refresh our meson build patch, and add a new meson patch for the tests. We also split out LIBVIRT_VERSION, so that nested builds can use it to locate tarballs. Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
67 lines
2.3 KiB
PHP
67 lines
2.3 KiB
PHP
inherit python3native python3-dir python3targetconfig
|
|
|
|
export STAGING_INCDIR
|
|
export STAGING_LIBDIR
|
|
export BUILD_SYS
|
|
export HOST_SYS
|
|
|
|
RDEPENDS:${PN}-python += "python3"
|
|
PACKAGECONFIG_${PN}-python[xen] = ",,,xen-python"
|
|
|
|
PACKAGES += "${PN}-python-staticdev ${PN}-python-dev ${PN}-python-dbg ${PN}-python"
|
|
|
|
FILES:${PN}-python-staticdev += "${PYTHON_SITEPACKAGES_DIR}/*.a"
|
|
FILES:${PN}-python-dev += "${PYTHON_SITEPACKAGES_DIR}/*.la"
|
|
FILES:${PN}-python-dbg += "${PYTHON_SITEPACKAGES_DIR}/.debug/"
|
|
FILES:${PN}-python = "${bindir}/* ${libdir}/* ${libdir}/${PYTHON_DIR}/*"
|
|
|
|
# Currently the libvirt-python debug libraries contain buildpaths
|
|
INSANE_SKIP:${PN}-dbg += "buildpaths"
|
|
|
|
SRC_URI += "http://libvirt.org/sources/python/${BPN}-python-${LIBVIRT_VERSION}.tar.gz;name=libvirt_python;subdir=${BP}"
|
|
|
|
SRC_URI[libvirt_python.sha256sum] = "785023500f58d3e8e829af98647d43eee97e517aacc9d9e7ded43594ea52d032"
|
|
|
|
export LIBVIRT_API_PATH = "${S}/docs/libvirt-api.xml"
|
|
export LIBVIRT_CFLAGS = "-I${S}/include"
|
|
export LIBVIRT_LIBS = "-L${B}/src/.libs -lvirt -ldl"
|
|
export LDFLAGS="-L${B}/src/.libs"
|
|
|
|
LIBVIRT_INSTALL_ARGS = "--root=${D} \
|
|
--prefix=${prefix} \
|
|
--install-lib=${PYTHON_SITEPACKAGES_DIR} \
|
|
--install-data=${datadir}"
|
|
|
|
python __anonymous () {
|
|
pkgconfig = d.getVar('PACKAGECONFIG')
|
|
if ('python') in pkgconfig.split():
|
|
d.setVar('LIBVIRT_PYTHON_ENABLE', '1')
|
|
else:
|
|
d.setVar('LIBVIRT_PYTHON_ENABLE', '0')
|
|
}
|
|
|
|
do_compile:append() {
|
|
if [ "${LIBVIRT_PYTHON_ENABLE}" = "1" ]; then
|
|
# we need the python bindings to look into our source dir, not
|
|
# the syroot staged pkgconfig entries. So we clear the sysroot
|
|
# for just this portion.
|
|
export PKG_CONFIG_SYSROOT_DIR=
|
|
cd ${UNPACKDIR}/${BP}/${BPN}-python-${LIBVIRT_VERSION} && \
|
|
${STAGING_BINDIR_NATIVE}/python3-native/python3 setup.py build
|
|
cd -
|
|
fi
|
|
}
|
|
|
|
do_install:append() {
|
|
if [ "${LIBVIRT_PYTHON_ENABLE}" = "1" ]; then
|
|
# we need the python bindings to look into our source dir, not
|
|
# the syroot staged pkgconfig entries. So we clear the sysroot
|
|
# for just this portion.
|
|
export PKG_CONFIG_SYSROOT_DIR=
|
|
cd ${UNPACKDIR}/${BP}/${BPN}-python-${LIBVIRT_VERSION} && \
|
|
${STAGING_BINDIR_NATIVE}/python3-native/python3 setup.py install \
|
|
--install-lib=${D}/${PYTHON_SITEPACKAGES_DIR} ${LIBVIRT_INSTALL_ARGS}
|
|
cd -
|
|
fi
|
|
}
|