mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
92c5e5ef61
The 'autogen.sh' script of crun was fetching dependencies that we already have in our SRC_URI. We want the OE git fetcher to manage the source, not scripts in the source of a package. We grab the two lines out of autogen.sh that we need, and use them directly in the configure_prepend. We also add yajl to the source code dependencies as the package DEPENDS is not enough as crun is explicitly building source that looks for the yajl code. Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
48 lines
1.7 KiB
BlitzBasic
48 lines
1.7 KiB
BlitzBasic
DESCRIPTION = "A fast and low-memory footprint OCI Container Runtime fully written in C."
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
PRIORITY = "optional"
|
|
|
|
SRCREV_crun = "360f5d02c37d5f7a67d38622010228ae2eeb80f1"
|
|
SRCREV_libocispec = "fb3c221d5849de9184f88b6929ce4a8c8fb55be9"
|
|
SRCREV_ispec = "54a822e528b91c8db63b873ad56daf200a2e5e61"
|
|
SRCREV_rspec = "ab23082b188344f6fbb63a441ea00ffc2852d06d"
|
|
SRCREV_yajl = "f344d21280c3e4094919fd318bc5ce75da91fc06"
|
|
|
|
SRCREV_FORMAT = "crun_rspec"
|
|
SRC_URI = "git://github.com/containers/crun.git;branch=main;name=crun \
|
|
git://github.com/containers/libocispec.git;branch=main;name=libocispec;destsuffix=git/libocispec \
|
|
git://github.com/opencontainers/runtime-spec.git;branch=master;name=rspec;destsuffix=git/libocispec/runtime-spec \
|
|
git://github.com/opencontainers/image-spec.git;branch=main;name=ispec;destsuffix=git/libocispec/image-spec \
|
|
git://github.com/containers/yajl.git;branch=main;name=yajl;destsuffix=git/libocispec/yajl \
|
|
"
|
|
|
|
PV = "0.18+git${SRCREV_crun}"
|
|
S = "${WORKDIR}/git"
|
|
|
|
REQUIRED_DISTRO_FEATURES ?= "systemd"
|
|
|
|
inherit autotools-brokensep pkgconfig features_check
|
|
|
|
PACKAGECONFIG ??= ""
|
|
|
|
inherit features_check
|
|
REQUIRED_DISTRO_FEATURES ?= "seccomp"
|
|
|
|
DEPENDS = "yajl libcap go-md2man-native m4-native"
|
|
# TODO: is there a packageconfig to turn this off ?
|
|
DEPENDS += "libseccomp"
|
|
DEPENDS += "systemd"
|
|
DEPENDS += "oci-image-spec oci-runtime-spec"
|
|
|
|
do_configure:prepend () {
|
|
# extracted from autogen.sh in crun source. This avoids
|
|
# git submodule fetching.
|
|
mkdir -p m4
|
|
autoreconf -fi
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
}
|