mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 20:59:41 +02:00
022ec69e9b
Bumping containerd to version v1.7.7-5-g5e21abb18, which comprises the following commits:
d0a1fedb5 *: add runc-fp as runc wrapper to inject failpoint
04491240a containerd-shim-runc-v2: avoid potential deadlock in create handler
6982a0df5 containerd-shim-runc-v2: remove unnecessary `s.getContainer()`
0e2320398 Uncopypaste parsing of OCI Bundle spec file
a34fa5681 Prepare release notes for v1.7.7
6ca0aebf0 Allow for images with artifacts to pull
7df492a95 remotes/docker: Fix MountedFrom prefixed with target repository
7779ce64e remotes: always try to establish tls connection when tls configured
b3db314a5 Bump x/net to 0.13
a83c66813 Require plugins to succeed after registering readiness
171d76849 cri: call RegisterReadiness after NewCRIService
6013b5e03 cri: stop recommending disable_cgroup
3d27bc738 Handle unexpected shim kill events
4ffa3ed29 Build binaries with 1.21.1
5756f6064 [release/1.7] vendor: github.com/Microsoft/hcsshim v0.11.1
09633b539 deprecate logs package, but disable linter (for transitioning)
cb201519f alias log package to github.com/containerd/log v0.1.0
a5024e6dd vendor: github.com/stretchr/testify v1.8.4
7bd976af3 vendor: github.com/sirupsen/logrus v1.9.3
3ca015e55 nri: update mock plugin handlers
4cd208c1f vendor: update github.com/containerd/nri@v0.4.0
8cd2d33c2 [release/1.7] remotes/docker: Add MountedFrom and Exists push status
3e09c65b2 Prepare release notes for v1.7.6
5ebf05d97 push: inherit distribution sources from parent
d206896dd content: add InfoProvider interface
423693d7b [release/1.7] update to go1.20.8
c7a35ccdc Fix transfer service dependencies:
38d4e506d Invoke Stable ABI compatibility function in windows platform matcher
ddffc7c9a Update hcsshim tag to v0.11.0
b449440a4 CRI: Support Linux usernames for !linux platforms
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
104 lines
3.6 KiB
BlitzBasic
104 lines
3.6 KiB
BlitzBasic
HOMEPAGE = "https://github.com/containerd/containerd"
|
|
SUMMARY = "containerd is a daemon to control runC"
|
|
DESCRIPTION = "containerd is a daemon to control runC, built for performance and density. \
|
|
containerd leverages runC's advanced features such as seccomp and user namespace \
|
|
support as well as checkpoint and restore for cloning and live migration of containers."
|
|
|
|
|
|
SRCREV = "5e21abb181c92adc95636edf983bdf639f0ceb60"
|
|
SRC_URI = "git://github.com/containerd/containerd;branch=release/1.7;protocol=https;destsuffix=git/src/github.com/containerd/containerd \
|
|
file://0001-Makefile-allow-GO_BUILD_FLAGS-to-be-externally-speci.patch \
|
|
file://0001-build-don-t-use-gcflags-to-define-trimpath.patch \
|
|
"
|
|
|
|
# Apache-2.0 for containerd
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1269f40c0d099c21a871163984590d89"
|
|
|
|
CONTAINERD_VERSION = "v1.7.7"
|
|
CVE_VERSION = "v1.7.7"
|
|
|
|
# EXTRA_OEMAKE += "GODEBUG=1"
|
|
|
|
PROVIDES += "virtual/containerd"
|
|
RPROVIDES:${PN} = "virtual-containerd"
|
|
|
|
S = "${WORKDIR}/git/src/github.com/containerd/containerd"
|
|
|
|
PV = "${CONTAINERD_VERSION}+git"
|
|
|
|
inherit go
|
|
inherit goarch
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
CONTAINERD_PKG="github.com/containerd/containerd"
|
|
|
|
INSANE_SKIP:${PN} += "ldflags"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
|
|
export GOPATH="${S}/src/import/.gopath:${S}/src/import/vendor:${STAGING_DIR_TARGET}/${prefix}/local/go:${WORKDIR}/git/"
|
|
export GOROOT="${STAGING_DIR_NATIVE}/${nonarch_libdir}/${HOST_SYS}/go"
|
|
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export BUILDTAGS="no_btrfs static_build netgo"
|
|
export CFLAGS="${CFLAGS}"
|
|
export LDFLAGS="${LDFLAGS}"
|
|
export SHIM_CGO_ENABLED="${CGO_ENABLED}"
|
|
# fixes:
|
|
# cannot find package runtime/cgo (using -importcfg)
|
|
# ... recipe-sysroot-native/usr/lib/aarch64-poky-linux/go/pkg/tool/linux_amd64/link:
|
|
# cannot open file : open : no such file or directory
|
|
export GO_BUILD_FLAGS="-trimpath -a -pkgdir dontusecurrentpkgs"
|
|
export GO111MODULE=off
|
|
|
|
cd ${S}
|
|
|
|
oe_runmake binaries
|
|
}
|
|
|
|
inherit systemd
|
|
SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${PN}','',d)}"
|
|
SYSTEMD_SERVICE:${PN} = "${@bb.utils.contains('DISTRO_FEATURES','systemd','containerd.service','',d)}"
|
|
|
|
do_install() {
|
|
mkdir -p ${D}/${bindir}
|
|
|
|
cp ${S}/bin/containerd ${D}/${bindir}/containerd
|
|
cp ${S}/bin/containerd-shim ${D}/${bindir}/containerd-shim
|
|
cp ${S}/bin/containerd-shim-runc-v1 ${D}/${bindir}/containerd-shim-runc-v1
|
|
cp ${S}/bin/containerd-shim-runc-v2 ${D}/${bindir}/containerd-shim-runc-v2
|
|
cp ${S}/bin/ctr ${D}/${bindir}/containerd-ctr
|
|
|
|
ln -sf containerd ${D}/${bindir}/docker-containerd
|
|
ln -sf containerd-shim ${D}/${bindir}/docker-containerd-shim
|
|
ln -sf containerd-ctr ${D}/${bindir}/docker-containerd-ctr
|
|
|
|
ln -sf containerd-ctr ${D}/${bindir}/ctr
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 644 ${S}/containerd.service ${D}/${systemd_unitdir}/system
|
|
# adjust from /usr/local/bin to /usr/bin/
|
|
sed -e "s:/usr/local/bin/containerd:${bindir}/containerd:g" -i ${D}/${systemd_unitdir}/system/containerd.service
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += "${systemd_system_unitdir}/*"
|
|
|
|
INSANE_SKIP:${PN} += "ldflags already-stripped"
|
|
|
|
COMPATIBLE_HOST = "^(?!(qemu)?mips).*"
|
|
|
|
RDEPENDS:${BPN} += " ${VIRTUAL-RUNTIME_container_runtime}"
|
|
|
|
CVE_PRODUCT = "containerd"
|