mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
de94eb1572
While testing the cni uprev by building in a container with network=none the following error was found: go: github.com/Microsoft/go-winio@v0.4.11: Get https://proxy.golang.org/github.com/%21microsoft/go-winio/@v/v0.4.11.mod: dial tcp: lookup proxy.golang.org on 128.224.144.130:53: dial udp 128.224.144.130:53: connect: network is unreachable After some digging through the go documentation it was found that the '-mod=vendor' is required for 'go build' to use shipped vendor modules when building modules. This can be confirmed by look at the 'build_linux.sh' script which is found in the plugins repo. By using '-mod=vendor' and also ensuring things are properly placed in the GOPATH (ie $B) we can avoid having to create many of the links we had been previously. We also put all the build artifacts into $B to avoid mixing source and build. Signed-off-by: Mark Asselstine <mark.asselstine@windriver.com> Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
71 lines
2.3 KiB
BlitzBasic
71 lines
2.3 KiB
BlitzBasic
HOMEPAGE = "https://github.com/containernetworking/cni"
|
|
SUMMARY = "Container Network Interface - networking for Linux containers"
|
|
DESCRIPTION = "CNI (Container Network Interface), a Cloud Native Computing \
|
|
Foundation project, consists of a specification and libraries for writing \
|
|
plugins to configure network interfaces in Linux containers, along with a \
|
|
number of supported plugins. CNI concerns itself only with network connectivity \
|
|
of containers and removing allocated resources when the container is deleted. \
|
|
Because of this focus, CNI has a wide range of support and the specification \
|
|
is simple to implement. \
|
|
"
|
|
|
|
SRCREV_cni = "4cfb7b568922a3c79a23e438dc52fe537fc9687e"
|
|
# Version 0.8.5
|
|
SRCREV_plugins = "1f33fb729ae2b8900785f896df2dc1f6fe5e8239"
|
|
SRC_URI = "\
|
|
git://github.com/containernetworking/cni.git;nobranch=1;name=cni \
|
|
git://github.com/containernetworking/plugins.git;nobranch=1;destsuffix=${S}/src/github.com/containernetworking/plugins;name=plugins \
|
|
"
|
|
|
|
RPROVIDES_${PN} += "kubernetes-cni"
|
|
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://src/import/LICENSE;md5=fa818a259cbed7ce8bc2a22d35a464fc"
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
PV = "0.7.1+git${SRCREV_cni}"
|
|
|
|
inherit go
|
|
inherit goarch
|
|
|
|
do_compile() {
|
|
mkdir -p ${S}/src/github.com/containernetworking
|
|
ln -sfr ${S}/src/import ${S}/src/github.com/containernetworking/cni
|
|
|
|
cd ${B}/src/github.com/containernetworking/cni/libcni
|
|
${GO} build
|
|
|
|
cd ${B}/src/github.com/containernetworking/cni/cnitool
|
|
${GO} build
|
|
|
|
cd ${B}/src/github.com/containernetworking/plugins
|
|
PLUGINS="$(ls -d plugins/meta/*; ls -d plugins/ipam/*; ls -d plugins/main/* | grep -v windows)"
|
|
mkdir -p ${B}/plugins/bin/
|
|
for p in $PLUGINS; do
|
|
plugin="$(basename "$p")"
|
|
echo "building: $p"
|
|
${GO} build -mod=vendor -o ${B}/plugins/bin/$plugin github.com/containernetworking/plugins/$p
|
|
done
|
|
}
|
|
|
|
do_install() {
|
|
localbindir="${libexecdir}/cni/"
|
|
|
|
install -d ${D}${localbindir}
|
|
install -d ${D}/${sysconfdir}/cni/net.d
|
|
|
|
install -m 755 ${S}/src/import/cnitool/cnitool ${D}/${localbindir}
|
|
install -m 755 -D ${B}/plugins/bin/* ${D}/${localbindir}
|
|
|
|
# Parts of k8s expect the cni binaries to be available in /opt/cni
|
|
install -d ${D}/opt/cni
|
|
ln -sf ${libexecdir}/cni/ ${D}/opt/cni/bin
|
|
}
|
|
|
|
FILES_${PN} += "${libexecdir}/cni/* /opt/cni/bin"
|
|
|
|
INSANE_SKIP_${PN} += "ldflags already-stripped"
|
|
|
|
deltask compile_ptest_base
|