mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 12:50:22 +02:00
ea2a7de432
Bumping containerd to version v2.0.0-rc.3-19-g741c4bde5, which comprises the following commits:
531da9960 Reduce scope of permissions in stale workflow
ed64e6503 core/mount: remove logrus import
ea8265fb1 core/transfer/local: remove logrus import
75fd7a5a7 pkg/shim: remove logrus imports
38e2f0038 Adds a mutex to protect fallback host
587ee80f6 pkg/tracing: LogrusHook.Fire: micro-optimisation
ccf793812 pkg/tracing: remove direct use of github.com/sirupsen/logrus
4203e2de8 pkg/tracing/plugin: rename var that collided with import
e2e09b384 pkg/tracing: rename func that shadowed builtin, rm makeSpanName
e69ad9442 build(deps): bump the k8s group across 1 directory with 4 updates
5b8dfbd11 Allow proxy plugins to have capabilities
cc2cedae0 Revert "install-runc: pin Go to 1.21"
3c097352a update runc binary to v1.1.13
8c13ed1b8 Prepare v2.0.0-rc.3 release
86b8a8824 Remove pkg/seed
09d3e20d3 Allow running test in usernamespace
8bcffa944 KEP-3619: Fine grained SupplementalGroups control
87dd4309d vendor: github.com/containerd/platforms v0.2.1
939135ae3 CI: golangci-lint v1.59.1
df7f6ba5b ctr: return explicit errors for flags unsupported by transfer service
686a610ee build(deps): bump github.com/checkpoint-restore/checkpointctl
156458e54 build(deps): bump the golang-x group with 2 updates
08c1e12e9 CI: add back EL 8
149ca6880 Update hcsshim tag to 0.12.4
b1a23c495 Fail integration test early when a plugin load fails
d23c4b8b5 Use unix and windows specific connection error checks
02b6c6939 Allow fallback across default ports
80ce8bd61 build(deps): bump github.com/containerd/containerd/api
cde2527fc ctr: pull: Do not ignore labels when transfer service is used
1c123efb4 Update Go version to 1.22.4
e1e793e4a Update rockylinux vagrant build
5611fdd4a Transfer: Push: Enable to specify platforms
0e8cc9146 Transfer: Push: fix failure on pushing duplicated blobs
4123170a3 *: export RemoveVolatileOption for CRI image volumes
3e71ccafc Add type alias for event Envelope
da1d9672f Enable imgcrypt in cri pull
9857afda4 Add vendor for github.com/containerd/imgcrypt
359d84351 Update api minimum go version to 1.21
2d73340c2 Explicitly set release latest to false
ca59fb0b4 Cleanup shim manager configuration
9831a62d7 auth: add span to FetchToken helpers
58be88189 sandbox: do retry for wait to remote sandbox controller
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
101 lines
3.6 KiB
BlitzBasic
101 lines
3.6 KiB
BlitzBasic
HOMEPAGE = "https://github.com/containerd/containerd"
|
|
SUMMARY = "containerd is a daemon to control runC"
|
|
DESCRIPTION = "containerd is a daemon to control runC, built for performance and density. \
|
|
containerd leverages runC's advanced features such as seccomp and user namespace \
|
|
support as well as checkpoint and restore for cloning and live migration of containers."
|
|
|
|
|
|
SRCREV = "741c4bde518f551613584f7365b95ac848dbe850"
|
|
SRC_URI = "git://github.com/containerd/containerd;branch=main;protocol=https;destsuffix=git/src/github.com/containerd/containerd/v2 \
|
|
file://0001-Makefile-allow-GO_BUILD_FLAGS-to-be-externally-speci.patch \
|
|
file://0001-build-don-t-use-gcflags-to-define-trimpath.patch \
|
|
"
|
|
|
|
# Apache-2.0 for containerd
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1269f40c0d099c21a871163984590d89"
|
|
|
|
CONTAINERD_VERSION = "v2.0.0-rc.3"
|
|
CVE_VERSION = "v2.0.0-beta.0"
|
|
|
|
# EXTRA_OEMAKE += "GODEBUG=1"
|
|
|
|
# containerd-opencontainers is to provide compatibility with external
|
|
# packagegroups / recipes that depend on the existing split of containerd
|
|
# between docker and opencontainers. We can drop it in the future.
|
|
PROVIDES += "virtual/containerd containerd-opencontainers"
|
|
RPROVIDES:${PN} = "virtual-containerd containerd-opencontainers"
|
|
|
|
S = "${WORKDIR}/git/src/github.com/containerd/containerd/v2"
|
|
|
|
PV = "${CONTAINERD_VERSION}+git"
|
|
|
|
inherit go
|
|
inherit goarch
|
|
|
|
GO_IMPORT = "import"
|
|
|
|
INSANE_SKIP:${PN} += "ldflags"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
do_compile() {
|
|
export GOARCH="${TARGET_GOARCH}"
|
|
|
|
export GOPATH="${S}/src/import/.gopath:${S}/src/import/vendor:${STAGING_DIR_TARGET}/${prefix}/local/go:${WORKDIR}/git/"
|
|
export GOROOT="${STAGING_DIR_NATIVE}/${nonarch_libdir}/${HOST_SYS}/go"
|
|
|
|
# Pass the needed cflags/ldflags so that cgo
|
|
# can find the needed headers files and libraries
|
|
export CGO_ENABLED="1"
|
|
export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
|
|
export BUILDTAGS="no_btrfs static_build netgo"
|
|
export CFLAGS="${CFLAGS}"
|
|
export LDFLAGS="${LDFLAGS}"
|
|
export SHIM_CGO_ENABLED="${CGO_ENABLED}"
|
|
# fixes:
|
|
# cannot find package runtime/cgo (using -importcfg)
|
|
# ... recipe-sysroot-native/usr/lib/aarch64-poky-linux/go/pkg/tool/linux_amd64/link:
|
|
# cannot open file : open : no such file or directory
|
|
export GO_BUILD_FLAGS="-trimpath -a -pkgdir dontusecurrentpkgs"
|
|
export GO111MODULE=off
|
|
|
|
cd ${S}
|
|
|
|
oe_runmake binaries
|
|
}
|
|
|
|
inherit systemd
|
|
SYSTEMD_PACKAGES = "${@bb.utils.contains('DISTRO_FEATURES','systemd','${PN}','',d)}"
|
|
SYSTEMD_SERVICE:${PN} = "${@bb.utils.contains('DISTRO_FEATURES','systemd','containerd.service','',d)}"
|
|
|
|
do_install() {
|
|
mkdir -p ${D}/${bindir}
|
|
|
|
cp ${S}/bin/containerd ${D}/${bindir}/containerd
|
|
cp ${S}/bin/containerd-shim-runc-v2 ${D}/${bindir}/containerd-shim-runc-v2
|
|
cp ${S}/bin/ctr ${D}/${bindir}/containerd-ctr
|
|
|
|
ln -sf containerd ${D}/${bindir}/docker-containerd
|
|
ln -sf containerd-ctr ${D}/${bindir}/docker-containerd-ctr
|
|
|
|
ln -sf containerd-ctr ${D}/${bindir}/ctr
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 644 ${S}/containerd.service ${D}/${systemd_unitdir}/system
|
|
# adjust from /usr/local/bin to /usr/bin/
|
|
sed -e "s:/usr/local/bin/containerd:${bindir}/containerd:g" -i ${D}/${systemd_unitdir}/system/containerd.service
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} += "${systemd_system_unitdir}/*"
|
|
|
|
INSANE_SKIP:${PN} += "ldflags already-stripped"
|
|
|
|
COMPATIBLE_HOST = "^(?!(qemu)?mips).*"
|
|
|
|
RDEPENDS:${PN} += " ${VIRTUAL-RUNTIME_container_runtime}"
|
|
|