mirror of
git://git.yoctoproject.org/meta-virtualization.git
synced 2025-07-19 20:59:41 +02:00
343da075d5
Bumping buildah to version v1.37.5-4-gc0602013a, which comprises the following commits:
e4deb56f6 [release-1.37][CI:DOCS] touchup changelog
f31d99d24 Update CHANGELOG.md
5fd40b989 [release-1.37] Bump Buildah to v1.37.5
b949f6572 Bump the containers/storage library to v1.55.1
cffa820dc Properly validate cache IDs and sources
93986b888 Packit: constrain koji job to fedora package to avoid dupes
9dfacbb47 Tag v1.37.4
b55cbb8eb vendor: update c/common to v0.60.4
e289e285d CVE-2024-9407: validate "bind-propagation" flag settings
956095ee1 [release-1.37] Bump to Buildah v1.37.3
8165aae9e Do not error on trying to write IMA xattr as rootless
a47261ec1 imagebuildah.StageExecutor: clean up volumes/volumeCache
7b28b9e4e `manifest add --artifact`: handle multiple values
8fb01fbc9 Packit: split out ELN jobs and reuse fedora downstream targets
a8f37392f Packit: Enable sidetags for bodhi updates
1c0e94ec6 Use Epoch: 2 and respect the epoch in dependencies.
eadda3bc0 [release-1.37] Bump Buildah to v1.37.2
a18969dea [release-1.37] Bump c/common to v0.60.2, c/image to v5.32.2
67cc51e90 [release-1.37] Bump to Buildah v1.37.1
02313cf69 [release-1.37] Bump c/common v0.60.1, c/image v5.32.1
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
67 lines
2.1 KiB
BlitzBasic
67 lines
2.1 KiB
BlitzBasic
HOMEPAGE = "https://buildah.io"
|
|
SUMMARY = "A tool that facilitates building OCI container images."
|
|
DESCRIPTION = "A tool that facilitates building OCI container images."
|
|
|
|
# Apache-2.0 for containerd
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://src/github.com/containers/buildah/LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
BUILDAH_VERSION = "1.37.5"
|
|
|
|
PV = "${BUILDAH_VERSION}"
|
|
|
|
inherit go
|
|
inherit goarch
|
|
inherit pkgconfig
|
|
|
|
# Rdepends on podman which needs seccomp and ipv6
|
|
inherit features_check
|
|
REQUIRED_DISTRO_FEATURES = "seccomp ipv6"
|
|
|
|
COMPATIBLE_HOST = "^(?!mips).*"
|
|
|
|
GO_IMPORT = "github.com/containers/buildah"
|
|
GO_INSTALL = "${GO_IMPORT}"
|
|
GO_WORKDIR = "${GO_INSTALL}"
|
|
GOBUILDFLAGS += "-mod vendor"
|
|
|
|
SRCREV_FORMAT = "buildah_storage"
|
|
SRCREV_buildah = "c0602013adc2142f017a6b973a70b33e57bd5539"
|
|
SRCREV_storage = "246ba3062e8b551026aef2708eee747014ce5c52"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/containers/buildah;branch=release-1.37;name=buildah;protocol=https;destsuffix=${GO_SRCURI_DESTSUFFIX} \
|
|
"
|
|
|
|
DEPENDS = "libdevmapper btrfs-tools gpgme"
|
|
RDEPENDS:${PN} = "cgroup-lite fuse-overlayfs libdevmapper podman"
|
|
RDEPENDS:${PN}-dev = "bash perl"
|
|
|
|
do_compile:prepend() {
|
|
cd ${S}/src/github.com/containers/buildah
|
|
}
|
|
|
|
go_do_compile() {
|
|
export TMPDIR="${GOTMPDIR}"
|
|
export AS='${CC} -c'
|
|
if [ -n "${GO_INSTALL}" ]; then
|
|
${GO} install ${GOBUILDFLAGS} ./cmd/buildah
|
|
${GO} install ${GOBUILDFLAGS} ./tests/imgtype/imgtype.go
|
|
${GO} install ${GOBUILDFLAGS} ./tests/copy/copy.go
|
|
fi
|
|
|
|
# x86 statically linked executable that we don't need
|
|
rm -f ${S}/src/github.com/containers/buildah/internal/mkcw/embed/entrypoint
|
|
}
|
|
|
|
do_install:append() {
|
|
dest_dir=${D}/${sysconfdir}/containers
|
|
mkdir -p ${dest_dir}
|
|
install -m 666 ${S}/src/github.com/containers/buildah/docs/samples/registries.conf ${dest_dir}/buildah.registries.conf.sample
|
|
install -m 666 ${S}/src/github.com/containers/buildah/tests/policy.json ${dest_dir}/buildah.policy.json.sample
|
|
}
|
|
|
|
INSANE_SKIP:${PN} = "already-stripped"
|