mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 21:09:03 +02:00
barebox: add initial support
This adds the support for the barebox bootloader to oe-core. The recipe is inspired by meta-ptx [1] but is a major rework of the one found there. Barebox comes with a wide range of supported architectures and follows the concepts of Linux in various aspects like the driver model, the shell, or the virtual file system. This not only eases porting Linux drivers but also makes barebox a developer-friendly and feature-rich bootloader alternative [2]. For barebox (like for the kernel or other bootloaders) it is quite likely that people will not just build the original recipe but need to adapt it, point to custom repositories, apply patch stacks, COMPATIBLE_MACHINE etc. They may also choose to have different recipe names for different variants. Having only a single .bb file and requiring to copy or .bbappend it is inconvenient and results in unnecessary code duplication. Therefore, the base support for building barebox is encapsulated in barebox.bbclass (like kernel.bbclass for the kernel). Adds barebox to maintainers.inc but excludes it from the maintainers check since with the current check mechanism barebox would be skipped (and making the check fail) due to not being the PREFERRED_PROVIDER for virtual/bootloader. [1] https://github.com/pengutronix/meta-ptx/tree/master/recipes-bsp/barebox [2] https://www.barebox.org/demo/?graphic=0 (From OE-Core rev: 5c69f5626278a6e9756188a5771b18075380f52d) Signed-off-by: Marco Felsch <m.felsch@pengutronix.de> Signed-off-by: Enrico Jorns <ejo@pengutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
Marco Felsch
Richard Purdie
parent
ba2fcb968e
commit
8ca1fd0b72
155
meta/classes-recipe/barebox.bbclass
Normal file
155
meta/classes-recipe/barebox.bbclass
Normal file
|
|
@ -0,0 +1,155 @@
|
|||
#
|
||||
# Copyright OpenEmbedded Contributors
|
||||
#
|
||||
# SPDX-License-Identifier: MIT
|
||||
#
|
||||
|
||||
inherit kernel-arch deploy cml1 pkgconfig
|
||||
|
||||
LICENSE ?= "GPL-2.0-only"
|
||||
|
||||
PROVIDES += "virtual/bootloader"
|
||||
|
||||
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
||||
|
||||
DEPENDS += "bison-native flex-native"
|
||||
|
||||
S = "${WORKDIR}/barebox-${PV}"
|
||||
B = "${WORKDIR}/build"
|
||||
|
||||
require conf/image-uefi.conf
|
||||
|
||||
# For some platforms and configuration, the barebox build process will require
|
||||
# additional host tools that can be activated/deactivated here.
|
||||
PACKAGECONFIG ??= "openssl libusb fit"
|
||||
|
||||
PACKAGECONFIG[openssl] = ",,openssl-native"
|
||||
PACKAGECONFIG[libusb] = ",,libusb1-native"
|
||||
PACKAGECONFIG[fit] = ",,u-boot-tools-native dtc-native"
|
||||
|
||||
export KBUILD_BUILD_USER ?= "oe-user"
|
||||
export KBUILD_BUILD_HOST ?= "oe-host"
|
||||
|
||||
# unlike the kernel, barebox may build against host tools like openssl
|
||||
export HOST_EXTRACFLAGS
|
||||
|
||||
def get_layer_rev(path):
|
||||
try:
|
||||
rev, _ = bb.process.run("git describe --match='' --always --dirty --broken", cwd=path)
|
||||
except bb.process.ExecutionError:
|
||||
rev = ""
|
||||
return rev.strip()
|
||||
|
||||
BAREBOX_BUILDSYSTEM_VERSION[doc] = "Build system version to add to the barebox image. By default this is the git description of the containing layer."
|
||||
BAREBOX_BUILDSYSTEM_VERSION ??= "${@get_layer_rev(os.path.dirname(d.getVar('FILE')))}"
|
||||
|
||||
BAREBOX_FIRMWARE_DIR[doc] = "Overwrite barebox' firmware blobs search directory (CONFIG_EXTRA_FIRMWARE_DIR) with this path, default ${B}/firmware"
|
||||
BAREBOX_FIRMWARE_DIR ??= "${B}/firmware"
|
||||
|
||||
EXTRA_OEMAKE = " \
|
||||
CROSS_COMPILE=${TARGET_PREFIX} -C ${S} O=${B} \
|
||||
BUILDSYSTEM_VERSION=${BAREBOX_BUILDSYSTEM_VERSION} \
|
||||
CONFIG_EXTRA_FIRMWARE_DIR=${BAREBOX_FIRMWARE_DIR} \
|
||||
PKG_CONFIG=pkg-config-native \
|
||||
CROSS_PKG_CONFIG=pkg-config \
|
||||
"
|
||||
|
||||
BAREBOX_CONFIG[doc] = "The barebox kconfig defconfig file. Not used if a file called defconfig is added to the SRC_URI."
|
||||
BAREBOX_CONFIG ?= ""
|
||||
|
||||
# prevent from acting as non-buildable provider
|
||||
python () {
|
||||
bareboxconfig = d.getVar('BAREBOX_CONFIG')
|
||||
bareboxdefconfig = 'file://defconfig' in d.getVar('SRC_URI')
|
||||
|
||||
if not bareboxconfig and not bareboxdefconfig:
|
||||
raise bb.parse.SkipRecipe("BAREBOX_CONFIG must be set in the %s machine configuration or file://defconfig must be given in SRC_URI." % d.getVar("MACHINE"))
|
||||
}
|
||||
|
||||
barebox_do_configure() {
|
||||
if [ -e ${UNPACKDIR}/defconfig ]; then
|
||||
cp ${UNPACKDIR}/defconfig ${B}/.config
|
||||
else
|
||||
if [ -n "${BAREBOX_CONFIG}" ]; then
|
||||
oe_runmake ${BAREBOX_CONFIG}
|
||||
else
|
||||
bbfatal "No defconfig given. Either add file 'file://defconfig' to SRC_URI or set BAREBOX_CONFIG"
|
||||
fi
|
||||
fi
|
||||
|
||||
${S}/scripts/kconfig/merge_config.sh -m .config ${@" ".join(find_cfgs(d))}
|
||||
cml1_do_configure
|
||||
}
|
||||
|
||||
BAREBOX_ENV_DIR[doc] = "Overlay the barebox built-in environment with the environment provided by the BSP if specified."
|
||||
BAREBOX_ENV_DIR ??= "${UNPACKDIR}/env/"
|
||||
|
||||
barebox_do_compile () {
|
||||
export userccflags="${TARGET_LDFLAGS}${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
|
||||
unset LDFLAGS
|
||||
unset CFLAGS
|
||||
unset CPPFLAGS
|
||||
unset CXXFLAGS
|
||||
unset MACHINE
|
||||
# Allow to use ${UNPACKDIR} in kconfig options to include additionally fetched files
|
||||
export UNPACKDIR=${UNPACKDIR}
|
||||
|
||||
if [ -d ${BAREBOX_ENV_DIR} ]; then
|
||||
BAREBOX_DEFAULT_ENV="$(grep ^CONFIG_DEFAULT_ENVIRONMENT_PATH .config | cut -d '=' -f 2 | tr -d '"')"
|
||||
oe_runmake CONFIG_DEFAULT_ENVIRONMENT_PATH="\"${BAREBOX_DEFAULT_ENV} ${BAREBOX_ENV_DIR}\""
|
||||
else
|
||||
oe_runmake
|
||||
fi
|
||||
}
|
||||
|
||||
BAREBOX_BINARY[doc] = "Specify the barebox binary to install. If not specified all barebox artifacts are installed."
|
||||
BAREBOX_BINARY ??= "${@'barebox.efi' if d.getVar('EFI_PROVIDER') == 'barebox' else ''}"
|
||||
BAREBOX_SUFFIX[doc] = "Specify the suffix for ${BAREBOX_IMAGE}."
|
||||
BAREBOX_SUFFIX ??= "img"
|
||||
BAREBOX_IMAGE[doc] = "A unique barebox image name. Unused if ${BAREBOX_BINARY} is not set."
|
||||
BAREBOX_IMAGE_DEFAULT ?= "${PN}-${MACHINE}-${PV}-${PR}.${BAREBOX_SUFFIX}"
|
||||
BAREBOX_IMAGE ?= "${@'${EFI_BOOT_IMAGE}' if d.getVar('EFI_PROVIDER') == 'barebox' else '${BAREBOX_IMAGE_DEFAULT}'}"
|
||||
|
||||
BAREBOX_INSTALL_PATH ?= "${@'${EFI_FILES_PATH}' if d.getVar('EFI_PROVIDER') == 'barebox' else '/boot'}"
|
||||
|
||||
barebox_do_install () {
|
||||
if [ -n "${BAREBOX_BINARY}" ]; then
|
||||
|
||||
BAREBOX_BIN=${B}/${BAREBOX_BINARY}
|
||||
if [ ! -f "${BAREBOX_BIN}" ]; then
|
||||
BAREBOX_BIN=${B}/images/${BAREBOX_BINARY}
|
||||
fi
|
||||
if [ ! -f "${BAREBOX_BIN}" ]; then
|
||||
bbfatal "Failed to locate ${BAREBOX_BINARY}"
|
||||
fi
|
||||
|
||||
install -D -m 644 ${BAREBOX_BIN} ${D}${BAREBOX_INSTALL_PATH}/${BAREBOX_IMAGE}
|
||||
ln -sf ${BAREBOX_IMAGE} ${D}${BAREBOX_INSTALL_PATH}/${BAREBOX_BINARY}
|
||||
else
|
||||
install -d ${D}${BAREBOX_INSTALL_PATH}/
|
||||
for image in $(cat ${B}/barebox-flash-images); do
|
||||
install -m 644 ${B}/${image} ${D}${BAREBOX_INSTALL_PATH}/
|
||||
done
|
||||
fi
|
||||
}
|
||||
FILES:${PN} = "${BAREBOX_INSTALL_PATH}"
|
||||
|
||||
barebox_do_deploy () {
|
||||
if [ -n "${BAREBOX_BINARY}" ]; then
|
||||
|
||||
BAREBOX_BIN=${B}/${BAREBOX_BINARY}
|
||||
if [ ! -f "${BAREBOX_BIN}" ]; then
|
||||
BAREBOX_BIN=${B}/images/${BAREBOX_BINARY}
|
||||
fi
|
||||
|
||||
install -D -m 644 ${BAREBOX_BIN} ${DEPLOYDIR}/${BAREBOX_IMAGE}
|
||||
ln -sf ${BAREBOX_IMAGE} ${DEPLOYDIR}/${BAREBOX_BINARY}
|
||||
else
|
||||
for image in $(cat ${B}/barebox-flash-images); do
|
||||
cp ${B}/${image} ${DEPLOYDIR}
|
||||
done
|
||||
fi
|
||||
}
|
||||
addtask deploy after do_compile
|
||||
|
||||
EXPORT_FUNCTIONS do_configure do_compile do_install do_deploy
|
||||
|
|
@ -54,6 +54,7 @@ RECIPE_MAINTAINER:pn-automake = "Robert Yang <liezhi.yang@windriver.com>"
|
|||
RECIPE_MAINTAINER:pn-avahi = "Yi Zhao <yi.zhao@windriver.com>"
|
||||
RECIPE_MAINTAINER:pn-babeltrace = "Alexander Kanavin <alex.kanavin@gmail.com>"
|
||||
RECIPE_MAINTAINER:pn-babeltrace2 = "Alexander Kanavin <alex.kanavin@gmail.com>"
|
||||
RECIPE_MAINTAINER:pn-barebox = "Enrico Jörns <yocto@pengutronix.de>"
|
||||
RECIPE_MAINTAINER:pn-baremetal-helloworld = "Alejandro Hernandez <alejandro@enedino.org>"
|
||||
RECIPE_MAINTAINER:pn-base-files = "Anuj Mittal <anuj.mittal@intel.com>"
|
||||
RECIPE_MAINTAINER:pn-base-passwd = "Anuj Mittal <anuj.mittal@intel.com>"
|
||||
|
|
|
|||
|
|
@ -56,7 +56,7 @@ but their recipes claim otherwise by setting UPSTREAM_VERSION_UNKNOWN. Please re
|
|||
|
||||
def is_maintainer_exception(entry):
|
||||
exceptions = ["musl", "newlib", "picolibc", "linux-yocto", "linux-dummy", "mesa-gl", "libgfortran", "libx11-compose-data",
|
||||
"cve-update-nvd2-native",]
|
||||
"cve-update-nvd2-native", "barebox"]
|
||||
for i in exceptions:
|
||||
if i in entry:
|
||||
return True
|
||||
|
|
|
|||
15
meta/recipes-bsp/barebox/barebox_2024.08.0.bb
Normal file
15
meta/recipes-bsp/barebox/barebox_2024.08.0.bb
Normal file
|
|
@ -0,0 +1,15 @@
|
|||
SUMMARY = "barebox is a bootloader designed for embedded systems. It runs on a variety of architectures including x86, ARM, MIPS, PowerPC and others."
|
||||
DESCRIPTION = "barebox aims to be a versatile and flexible bootloader not only for booting embedded Linux systems, \
|
||||
but also for initial hardware bringup and development. \
|
||||
Users should feel right at home with a shell with UNIX-like virtual file system access to hardware, \
|
||||
Linux kernel driver API for making driver porting easier, \
|
||||
and a subset of the POSIX C library for writing more command-line utilities."
|
||||
HOMEPAGE = "https://barebox.org/"
|
||||
SECTION = "bootloaders"
|
||||
|
||||
LIC_FILES_CHKSUM = "file://COPYING;md5=f5125d13e000b9ca1f0d3364286c4192"
|
||||
|
||||
inherit barebox
|
||||
|
||||
SRC_URI = "https://barebox.org/download/barebox-${PV}.tar.bz2"
|
||||
SRC_URI[sha256sum] = "b08a762da8d63dd18b4f2d9f5d0a8da001b6e608d1b3eff6dcebc6a2e575d535"
|
||||
Loading…
Reference in New Issue
Block a user