mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-05 05:04:44 +02:00
1cebd3469e
After changing autotools.bbclass, CONFIG_SHELL setting no longer works resulting in: grep-3.4-r0 do_package_qa: QA Issue: /bin/fgrep.grep contained in package grep requires /bin/bash, but no providers found in RDEPENDS_grep? [file-rdeps] The script can use /bin/sh so set this specifically using sed since we want to use a consistent shell for the rest of the build but not have the specific bash dependency. (From OE-Core rev: 9031b66c7c817b65f75b429db6f6527d07196e8a) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
45 lines
1.3 KiB
BlitzBasic
45 lines
1.3 KiB
BlitzBasic
SUMMARY = "GNU grep utility"
|
|
HOMEPAGE = "http://savannah.gnu.org/projects/grep/"
|
|
BUGTRACKER = "http://savannah.gnu.org/bugs/?group=grep"
|
|
SECTION = "console/utils"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/grep/grep-${PV}.tar.xz"
|
|
|
|
SRC_URI[md5sum] = "111b117d22d6a7d049d6ae7505e9c4d2"
|
|
SRC_URI[sha256sum] = "58e6751c41a7c25bfc6e9363a41786cff3ba5709cf11d5ad903cf7cce31cc3fb"
|
|
|
|
inherit autotools gettext texinfo pkgconfig
|
|
|
|
# Fix "Argument list too long" error when len(TMPDIR) = 410
|
|
acpaths = "-I ./m4"
|
|
|
|
do_configure_prepend () {
|
|
sed -i -e '1s,#!@SHELL@,#!/bin/sh,' ${S}/src/egrep.sh
|
|
rm -f ${S}/m4/init.m4
|
|
}
|
|
|
|
do_install () {
|
|
autotools_do_install
|
|
if [ "${base_bindir}" != "${bindir}" ]; then
|
|
install -d ${D}${base_bindir}
|
|
mv ${D}${bindir}/grep ${D}${base_bindir}/grep
|
|
mv ${D}${bindir}/egrep ${D}${base_bindir}/egrep
|
|
mv ${D}${bindir}/fgrep ${D}${base_bindir}/fgrep
|
|
rmdir ${D}${bindir}/
|
|
fi
|
|
}
|
|
|
|
inherit update-alternatives
|
|
|
|
PACKAGECONFIG ??= "pcre"
|
|
PACKAGECONFIG[pcre] = "--enable-perl-regexp,--disable-perl-regexp,libpcre"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE_${PN} = "grep egrep fgrep"
|
|
ALTERNATIVE_LINK_NAME[grep] = "${base_bindir}/grep"
|
|
ALTERNATIVE_LINK_NAME[egrep] = "${base_bindir}/egrep"
|
|
ALTERNATIVE_LINK_NAME[fgrep] = "${base_bindir}/fgrep"
|