mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 21:09:03 +02:00
5b33b053c1
* the class sets defaults used most common which can be overriden by recipes * UNKNOWN_CONFIGURE_WHITELIST was removed for autotools (and not added for meson) as suggested by Alexander Kanavin [1] [1] http://lists.openembedded.org/pipermail/openembedded-core/2019-April/280716.html (From OE-Core rev: 59589383131df6bc0c8787cd00a16ee59e21d441) Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
2.7 KiB
Plaintext
54 lines
2.7 KiB
Plaintext
# Inherit this class in recipes to enable building their introspection files
|
|
|
|
# python3native is inherited to prevent introspection tools being run with
|
|
# host's python 3 (they need to be run with native python 3)
|
|
#
|
|
# This also sets up autoconf-based recipes to build introspection data (or not),
|
|
# depending on distro and machine features (see gobject-introspection-data class).
|
|
inherit python3native gobject-introspection-data
|
|
|
|
# meson: default option name to enable/disable introspection. This matches most
|
|
# project's configuration. In doubts - check meson_options.txt in project's
|
|
# source path.
|
|
GIR_MESON_OPTION ?= 'introspection'
|
|
GIR_MESON_ENABLE_FLAG ?= 'true'
|
|
GIR_MESON_DISABLE_FLAG ?= 'false'
|
|
|
|
# Auto enable/disable based on GI_DATA_ENABLED
|
|
EXTRA_OECONF_prepend_class-target = "${@bb.utils.contains('GI_DATA_ENABLED', 'True', '--enable-introspection', '--disable-introspection', d)} "
|
|
EXTRA_OEMESON_prepend_class-target = "-D${GIR_MESON_OPTION}=${@bb.utils.contains('GI_DATA_ENABLED', 'True', '${GIR_MESON_ENABLE_FLAG}', '${GIR_MESON_DISABLE_FLAG}', d)} "
|
|
|
|
# When building native recipes, disable introspection, as it is not necessary,
|
|
# pulls in additional dependencies, and makes build times longer
|
|
EXTRA_OECONF_prepend_class-native = "--disable-introspection "
|
|
EXTRA_OECONF_prepend_class-nativesdk = "--disable-introspection "
|
|
EXTRA_OEMESON_prepend_class-native = "-D${GIR_MESON_OPTION}=${GIR_MESON_DISABLE_FLAG} "
|
|
EXTRA_OEMESON_prepend_class-nativesdk = "-D${GIR_MESON_OPTION}=${GIR_MESON_DISABLE_FLAG} "
|
|
|
|
# Generating introspection data depends on a combination of native and target
|
|
# introspection tools, and qemu to run the target tools.
|
|
DEPENDS_append_class-target = " gobject-introspection gobject-introspection-native qemu-native prelink-native"
|
|
|
|
# Even though introspection is disabled on -native, gobject-introspection package is still
|
|
# needed for m4 macros.
|
|
DEPENDS_append_class-native = " gobject-introspection-native"
|
|
DEPENDS_append_class-nativesdk = " gobject-introspection-native"
|
|
|
|
# This is used by introspection tools to find .gir includes
|
|
export XDG_DATA_DIRS = "${STAGING_DATADIR}:${STAGING_LIBDIR}"
|
|
|
|
do_configure_prepend_class-target () {
|
|
# introspection.m4 pre-packaged with upstream tarballs does not yet
|
|
# have our fixes
|
|
mkdir -p ${S}/m4
|
|
cp ${STAGING_DIR_TARGET}/${datadir}/aclocal/introspection.m4 ${S}/m4
|
|
}
|
|
|
|
# .typelib files are needed at runtime and so they go to the main package (so
|
|
# they'll be together with libraries they support).
|
|
FILES_${PN}_append = " ${libdir}/girepository-*/*.typelib"
|
|
|
|
# .gir files go to dev package, as they're needed for developing (but not for
|
|
# running) things that depends on introspection.
|
|
FILES_${PN}-dev_append = " ${datadir}/gir-*/*.gir ${libdir}/gir-*/*.gir"
|