mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 21:09:03 +02:00
c62ad6939f
Instead of assuming that the schemas are located in ${PN}, add a
GSETTINGS_PACKAGE variable for the package name and default it to ${PN}.
For recipe that can conditionally ship schemas, support GSETTINGS_PACKAGE being
empty gracefully by doing nothing.
(From OE-Core rev: c2b9c34ce4af151cc0422e14af775c6c962de051)
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.4 KiB
Plaintext
43 lines
1.4 KiB
Plaintext
# A bbclass to handle installed GSettings (glib) schemas, updated the compiled
|
|
# form on package install and remove.
|
|
#
|
|
# The compiled schemas are platform-agnostic, so we can depend on
|
|
# glib-2.0-native for the native tool and run the postinst script when the
|
|
# rootfs builds to save a little time on first boot.
|
|
|
|
# TODO use a trigger so that this runs once per package operation run
|
|
|
|
GSETTINGS_PACKAGE ?= "${PN}"
|
|
|
|
python __anonymous() {
|
|
pkg = d.getVar("GSETTINGS_PACKAGE")
|
|
if pkg:
|
|
d.appendVar("PACKAGE_WRITE_DEPS", " glib-2.0-native")
|
|
d.appendVar("RDEPENDS_" + pkg, " ${MLPREFIX}glib-2.0-utils")
|
|
d.appendVar("FILES_" + pkg, " ${datadir}/glib-2.0/schemas")
|
|
}
|
|
|
|
gsettings_postinstrm () {
|
|
glib-compile-schemas $D${datadir}/glib-2.0/schemas
|
|
}
|
|
|
|
python populate_packages_append () {
|
|
pkg = d.getVar('GSETTINGS_PACKAGE')
|
|
if pkg:
|
|
bb.note("adding gsettings postinst scripts to %s" % pkg)
|
|
|
|
postinst = d.getVar('pkg_postinst_%s' % pkg) or d.getVar('pkg_postinst')
|
|
if not postinst:
|
|
postinst = '#!/bin/sh\n'
|
|
postinst += d.getVar('gsettings_postinstrm')
|
|
d.setVar('pkg_postinst_%s' % pkg, postinst)
|
|
|
|
bb.note("adding gsettings postrm scripts to %s" % pkg)
|
|
|
|
postrm = d.getVar('pkg_postrm_%s' % pkg) or d.getVar('pkg_postrm')
|
|
if not postrm:
|
|
postrm = '#!/bin/sh\n'
|
|
postrm += d.getVar('gsettings_postinstrm')
|
|
d.setVar('pkg_postrm_%s' % pkg, postrm)
|
|
}
|