mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 21:09:03 +02:00
c814947e03
PATCH REBASED: ============== 0001-do-not-disable-buffer-in-writing-files.patch 0002-don-t-use-glibc-specific-qsort_r.patch 0003-missing_type.h-add-__compare_fn_t-and-comparison_fn_.patch 0004-add-fallback-parse_printf_format-implementation.patch 0005-rules-watch-metadata-changes-in-ide-devices.patch 0005-src-basic-missing.h-check-for-missing-strndupa.patch 0007-don-t-fail-if-GLOB_BRACE-and-GLOB_ALTDIRFUNC-is-not.patch 0009-socket-util-don-t-fail-if-libc-doesn-t-support-IDN.patch 0017-Do-not-disable-buffering-when-writing-to-oom_score_a.patch 0021-avoid-redefinition-of-prctl_mm_map-structure.patch 0024-test-json.c-define-M_PIl.patch PATCH DROPPED: ============== 0001-meson-declare-version.h-as-dep-for-various-targets-t.patch 0001-meson-declare-version.h-as-dependency-for-systemd.patch 0013-test-hexdecoct.c-Include-missing.h-for-strndupa.patch PATCH ADDED: 0025-fs-utilh-add-missing-sys-stat-include.patch (From OE-Core rev: 1d453c9087f92da1ceddc66a887941e4929b3448) Signed-off-by: Andrej Valek <andrej.valek@siemens.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
72 lines
2.3 KiB
BlitzBasic
72 lines
2.3 KiB
BlitzBasic
require systemd.inc
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemd:"
|
|
|
|
DEPENDS = "intltool-native libcap util-linux gnu-efi gperf-native"
|
|
|
|
# NOTE: These three patches are in theory not needed, but we haven't
|
|
# figured out how to correctly pass efi-cc parameter if it's an array.
|
|
SRC_URI += "file://0001-Revert-meson-use-an-array-option-for-efi-cc.patch \
|
|
file://0001-Revert-meson-print-EFI-CC-configuration-nicely.patch \
|
|
file://0001-Fix-to-run-efi_cc-and-efi_ld-correctly-when-cross-co.patch \
|
|
"
|
|
|
|
inherit meson pkgconfig gettext
|
|
inherit deploy
|
|
|
|
EFI_CC ?= "${CC}"
|
|
EXTRA_OEMESON += "-Defi=true \
|
|
-Dgnu-efi=true \
|
|
-Defi-includedir=${STAGING_INCDIR}/efi \
|
|
-Defi-ldsdir=${STAGING_LIBDIR} \
|
|
-Defi-libdir=${STAGING_LIBDIR} \
|
|
-Dman=false \
|
|
-Defi-cc='${EFI_CC}' \
|
|
-Defi-ld='${LD}' \
|
|
"
|
|
|
|
# install to the image as boot*.efi if its the EFI_PROVIDER,
|
|
# otherwise install as the full name.
|
|
# This allows multiple bootloaders to coexist in a single image.
|
|
python __anonymous () {
|
|
import re
|
|
target = d.getVar('TARGET_ARCH')
|
|
prefix = "" if d.getVar('EFI_PROVIDER') == "systemd-boot" else "systemd-"
|
|
if target == "x86_64":
|
|
systemdimage = prefix + "bootx64.efi"
|
|
else:
|
|
systemdimage = prefix + "bootia32.efi"
|
|
d.setVar("SYSTEMD_BOOT_IMAGE", systemdimage)
|
|
prefix = "systemd-" if prefix == "" else ""
|
|
d.setVar("SYSTEMD_BOOT_IMAGE_PREFIX", prefix)
|
|
}
|
|
|
|
FILES_${PN} = "/boot/EFI/BOOT/${SYSTEMD_BOOT_IMAGE}"
|
|
|
|
RDEPENDS_${PN} += "virtual/systemd-bootconf"
|
|
|
|
# Imported from the old gummiboot recipe
|
|
TUNE_CCARGS_remove = "-mfpmath=sse"
|
|
COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
|
|
COMPATIBLE_HOST_x86-x32 = "null"
|
|
|
|
do_compile() {
|
|
SYSTEMD_BOOT_EFI_ARCH="ia32"
|
|
if [ "${TARGET_ARCH}" = "x86_64" ]; then
|
|
SYSTEMD_BOOT_EFI_ARCH="x64"
|
|
fi
|
|
|
|
ninja src/boot/efi/${SYSTEMD_BOOT_IMAGE_PREFIX}${SYSTEMD_BOOT_IMAGE}
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/boot
|
|
install -d ${D}/boot/EFI
|
|
install -d ${D}/boot/EFI/BOOT
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${D}/boot/EFI/BOOT/${SYSTEMD_BOOT_IMAGE}
|
|
}
|
|
|
|
do_deploy () {
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${DEPLOYDIR}
|
|
}
|
|
addtask deploy before do_build after do_compile
|