mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 12:59:02 +02:00
c2da016918
Recipes are much more readable with whitespace around the assignment operators. Fix various assignments in OE-Core to show this is definitely the preferred formatting. (From OE-Core rev: 30ea609d3357fb3de911f2f6a5e6856c151b976a) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.4 KiB
BlitzBasic
43 lines
1.4 KiB
BlitzBasic
SUMMARY = "XML::Parser - A perl module for parsing XML documents"
|
|
HOMEPAGE = "https://libexpat.github.io/"
|
|
SECTION = "libs"
|
|
LICENSE = "Artistic-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=4342f85bf14a1fdd6a751573f1e61c03"
|
|
|
|
DEPENDS += "expat"
|
|
|
|
SRC_URI = "http://www.cpan.org/modules/by-module/XML/XML-Parser-${PV}.tar.gz \
|
|
file://0001-Makefile.PL-make-check_lib-cross-friendly.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "ad4aae643ec784f489b956abe952432871a622d4e2b5c619e8855accbfc4d1d8"
|
|
|
|
S = "${WORKDIR}/XML-Parser-${PV}"
|
|
|
|
EXTRA_CPANFLAGS = "EXPATLIBPATH=${STAGING_LIBDIR} EXPATINCPATH=${STAGING_INCDIR} CC='${CC}' LD='${CCLD}' FULL_AR='${AR}'"
|
|
|
|
inherit cpan pkgconfig ptest-perl
|
|
|
|
do_compile() {
|
|
export LIBC="$(find ${STAGING_DIR_TARGET}/${base_libdir}/ -name 'libc-*.so')"
|
|
cpan_do_compile
|
|
}
|
|
|
|
do_compile:class-native() {
|
|
cpan_do_compile
|
|
}
|
|
|
|
do_install_ptest() {
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/xmlstats
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/xmlfilter
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/xmlcomments
|
|
sed -i -e "s:/usr/local/bin/perl:/usr/bin/perl:g" ${B}/samples/canonical
|
|
cp -r ${B}/samples ${D}${PTEST_PATH}
|
|
chown -R root:root ${D}${PTEST_PATH}/samples
|
|
}
|
|
|
|
RDEPENDS:${PN} += "perl-module-carp perl-module-file-spec"
|
|
RDEPENDS:${PN}-ptest += "perl-module-filehandle perl-module-if perl-module-test perl-module-test-more"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|