mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 12:59:02 +02:00
c2da016918
Recipes are much more readable with whitespace around the assignment operators. Fix various assignments in OE-Core to show this is definitely the preferred formatting. (From OE-Core rev: 30ea609d3357fb3de911f2f6a5e6856c151b976a) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.4 KiB
BlitzBasic
41 lines
1.4 KiB
BlitzBasic
SUMMARY = "Python GObject bindings"
|
|
HOMEPAGE = "https://gitlab.gnome.org/GNOME/pygobject"
|
|
DESCRIPTION = "PyGObject is a Python package which provides bindings for GObject based libraries such as GTK, GStreamer, WebKitGTK, GLib, GIO and many more."
|
|
SECTION = "devel/python"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a916467b91076e631dd8edb7424769c7"
|
|
|
|
GIR_MESON_OPTION = ""
|
|
|
|
inherit gnomebase setuptools3-base gobject-introspection upstream-version-is-even
|
|
|
|
python() {
|
|
if d.getVar('CLASSOVERRIDE') == "class-target" and not bb.utils.to_boolean(d.getVar("GI_DATA_ENABLED")):
|
|
raise bb.parse.SkipRecipe("GI not available")
|
|
}
|
|
|
|
DEPENDS += "python3 glib-2.0"
|
|
|
|
SRCNAME = "pygobject"
|
|
|
|
SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/${SRCNAME}/${@gnome_verdir("${PV}")}/${SRCNAME}-${PV}.tar.xz"
|
|
SRC_URI[sha256sum] = "8d836e75b5a881d457ee1622cae4a32bcdba28a0ba562193adb3bbb472472212"
|
|
|
|
S = "${WORKDIR}/${SRCNAME}-${PV}"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains_any('DISTRO_FEATURES', [ 'directfb', 'wayland', 'x11' ], 'cairo', '', d)}"
|
|
|
|
RDEPENDS:${PN} += " \
|
|
python3-asyncio \
|
|
python3-io \
|
|
python3-pkgutil \
|
|
"
|
|
|
|
# python3-pycairo is checked on configuration -> DEPENDS
|
|
# we don't link against python3-pycairo -> RDEPENDS
|
|
PACKAGECONFIG[cairo] = "-Dpycairo=enabled,-Dpycairo=disabled, cairo python3-pycairo, python3-pycairo"
|
|
PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
PACKAGECONFIG:class-native = ""
|