mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 12:59:02 +02:00
90e0a0f7f4
The idea of the base class dependency is to say "yes, I need a C cross compiler" and this was never meant to be gcc specific. Looking at the codebase, whilst we code triplets into this, it does overcomplicate things as there are only ever limited, "target", "sdk" and the class extended versions like mutlilib. After much thought, we can simplify this to virtual/cross-cc and virtual/nativesdk-cross-cc. This lets us remove the "gcc" specific element as well as removing the over complicated triplet usage. At the same time, change the much less widely used "g++" variant to "c++" for similar reasons and remove the triplet from virtual/XXX-binutils too. Backwards compatibility mappings could be left but are just going to confuse things in future so we'll just require users to update. This simplification, whilst disruptive for any toolchain focused layers, will make improved toolchain selection in the future much easier. Since we no longer have overlapping variables, some code for that can just be removed. The class extension code does need to start remapping some variables but not the crosssdk target recipe names. This patch is in two pieces, this one handles the renaming with the functional changes separate in a second for easier review even if this breaks bisection. (From OE-Core rev: 4ccc3bc8266c327bcc18c9a3faf7536210dfb9f0) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
57 lines
1.8 KiB
PHP
57 lines
1.8 KiB
PHP
require glibc-common.inc
|
|
require glibc-ld.inc
|
|
|
|
DEPENDS = "virtual/cross-cc virtual/cross-binutils libgcc-initial linux-libc-headers"
|
|
|
|
PROVIDES = "virtual/libc"
|
|
PROVIDES += "virtual/libintl virtual/libiconv"
|
|
inherit autotools texinfo systemd
|
|
|
|
LEAD_SONAME = "libc.so"
|
|
|
|
# msgfmt could come from gettext-native but we don't depend on that and
|
|
# disable for reproducibility
|
|
CACHED_CONFIGUREVARS += " \
|
|
ac_cv_path_BASH_SHELL=${base_bindir}/bash \
|
|
ac_cv_prog_MSGFMT= \
|
|
libc_cv_slibdir=${base_libdir} \
|
|
libc_cv_rootsbindir=${base_sbindir} \
|
|
libc_cv_localedir=${localedir} \
|
|
libc_cv_ssp_strong=no \
|
|
libc_cv_ssp_all=no \
|
|
libc_cv_ssp=no \
|
|
libc_cv_include_x86_isa_level=no \
|
|
"
|
|
|
|
# ifunc doesn't appear to work on mips, casuses libbfd assertion failures
|
|
CACHED_CONFIGUREVARS:append:mipsarch = " libc_cv_ld_gnu_indirect_function=no"
|
|
|
|
GLIBC_EXTRA_OECONF ?= ""
|
|
GLIBC_EXTRA_OECONF:class-nativesdk = ""
|
|
|
|
# glibc uses PARALLELMFLAGS variable to pass parallel build info so transfer
|
|
# PARALLEL_MAKE into PARALLELMFLAGS and empty out PARALLEL_MAKE
|
|
EGLIBCPARALLELISM := "PARALLELMFLAGS="${PARALLEL_MAKE}""
|
|
EXTRA_OEMAKE[vardepsexclude] += "EGLIBCPARALLELISM"
|
|
EXTRA_OEMAKE += "${EGLIBCPARALLELISM}"
|
|
PARALLEL_MAKE = ""
|
|
|
|
# glibc make-syscalls.sh has a number of issues with /bin/dash and
|
|
# it's output which make calls via the SHELL also has issues, so
|
|
# ensure make uses /bin/bash
|
|
EXTRA_OEMAKE += "SHELL=/bin/bash"
|
|
|
|
# We do not need bash to run tzselect script, the default is to use
|
|
# bash but it can be configured by setting KSHELL Makefile variable
|
|
EXTRA_OEMAKE += "KSHELL=/bin/sh"
|
|
|
|
do_configure:prepend() {
|
|
sed -e "s#/bin/bash#/bin/sh#" -i ${S}/elf/ldd.bash.in
|
|
}
|
|
|
|
# Enable backtrace from abort()
|
|
do_configure:append:arm () {
|
|
echo "CFLAGS-abort.c = -fasynchronous-unwind-tables" >> ${B}/configparms
|
|
echo "CFLAGS-raise.c = -fasynchronous-unwind-tables" >> ${B}/configparms
|
|
}
|