mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-05 05:04:44 +02:00
dc9faa3cdc
Some of them were introduced by mass-removal of S = WORKDIR/git assignments;
rather than try to fix up (or redo) just these, I've run this sed command over
the whole tree:
sed -i -z -E 's/([ \t\f\v\r]*\n){3,}/\n\n/g' `find . -name *.bb -o -name *.inc`
The rationale is that more than one empty line is wasting vertical screen space, and
does nothing for readability.
(From OE-Core rev: cedc4ff7c9bcfb22a20e43e47f9759f4007a4f1a)
Signed-off-by: Alexander Kanavin <alex@linutronix.de>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
84 lines
3.5 KiB
BlitzBasic
84 lines
3.5 KiB
BlitzBasic
SUMMARY = "Open Package Manager"
|
|
SUMMARY:libopkg = "Open Package Manager library"
|
|
SECTION = "base"
|
|
HOMEPAGE = "https://git.yoctoproject.org/opkg/"
|
|
DESCRIPTION = "Opkg is a lightweight package management system based on Ipkg."
|
|
BUGTRACKER = "https://bugzilla.yoctoproject.org/buglist.cgi?quicksearch=Product%3Aopkg"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://src/opkg.c;beginline=4;endline=18;md5=d6200b0f2b41dee278aa5fad333eecae"
|
|
|
|
DEPENDS = "libarchive zstd"
|
|
|
|
PE = "1"
|
|
|
|
SRC_URI = "http://downloads.yoctoproject.org/releases/${BPN}/${BPN}-${PV}.tar.gz \
|
|
file://opkg.conf \
|
|
file://0001-opkg_conf-create-opkg.lock-in-run-instead-of-var-run.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "d973fd0f1568f58f87d6aecd9aa95e3e1f60214a45cee26704bf8fe757c54567"
|
|
|
|
# This needs to be before ptest inherit, otherwise all ptest files end packaged
|
|
# in libopkg package if OPKGLIBDIR == libdir, because default
|
|
# PTEST_PATH ?= "${libdir}/${BPN}/ptest"
|
|
PACKAGES =+ "libopkg"
|
|
|
|
inherit autotools pkgconfig ptest
|
|
|
|
target_localstatedir := "${localstatedir}"
|
|
OPKGLIBDIR ??= "${target_localstatedir}/lib"
|
|
|
|
PACKAGECONFIG ??= "libsolv"
|
|
|
|
PACKAGECONFIG[gpg] = "--enable-gpg,--disable-gpg,\
|
|
gnupg gpgme libgpg-error,\
|
|
${@ "gnupg" if ("native" in d.getVar("PN")) else "gnupg-gpg"}\
|
|
"
|
|
PACKAGECONFIG[curl] = "--enable-curl,--disable-curl,curl"
|
|
PACKAGECONFIG[ssl-curl] = "--enable-ssl-curl,--disable-ssl-curl,curl openssl"
|
|
PACKAGECONFIG[sha256] = "--enable-sha256,--disable-sha256"
|
|
PACKAGECONFIG[libsolv] = "--with-libsolv,--without-libsolv,libsolv"
|
|
|
|
EXTRA_OECONF = "--enable-zstd"
|
|
EXTRA_OECONF:append:class-native = " --localstatedir=/${@os.path.relpath('${localstatedir}', '${STAGING_DIR_NATIVE}')} --sysconfdir=/${@os.path.relpath('${sysconfdir}', '${STAGING_DIR_NATIVE}')}"
|
|
|
|
do_install:append () {
|
|
install -d ${D}${sysconfdir}/opkg
|
|
install -m 0644 ${UNPACKDIR}/opkg.conf ${D}${sysconfdir}/opkg/opkg.conf
|
|
echo "option lists_dir ${OPKGLIBDIR}/opkg/lists" >>${D}${sysconfdir}/opkg/opkg.conf
|
|
echo "option info_dir ${OPKGLIBDIR}/opkg/info" >>${D}${sysconfdir}/opkg/opkg.conf
|
|
echo "option status_file ${OPKGLIBDIR}/opkg/status" >>${D}${sysconfdir}/opkg/opkg.conf
|
|
|
|
# We need to create the lock directory
|
|
install -d ${D}${OPKGLIBDIR}/opkg
|
|
}
|
|
|
|
do_install_ptest () {
|
|
sed -i -e '/@echo $^/d' ${D}${PTEST_PATH}/tests/Makefile
|
|
sed -i -e '/@PYTHONPATH=. $(PYTHON) $^/a\\t@if [ "$$?" != "0" ];then echo "FAIL:"$^;else echo "PASS:"$^;fi' ${D}${PTEST_PATH}/tests/Makefile
|
|
}
|
|
|
|
WARN_QA:append = " internal-solver-deprecation"
|
|
QARECIPETEST[internal-solver-deprecation] = "qa_check_solver_deprecation"
|
|
def qa_check_solver_deprecation (pn, d):
|
|
pkgconfig = (d.getVar("PACKAGECONFIG") or "").split()
|
|
|
|
if "libsolv" not in pkgconfig:
|
|
oe.qa.handle_error("internal-solver-deprecation", "The opkg internal solver will be deprecated in future opkg releases. Consider enabling \"libsolv\" in PACKAGECONFIG.", d)
|
|
|
|
RDEPENDS:${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-arch-config libarchive"
|
|
RDEPENDS:${PN}:class-native = ""
|
|
RDEPENDS:${PN}:class-nativesdk = ""
|
|
RDEPENDS:${PN}-ptest += "make binutils python3-core python3-compression bash python3-crypt python3-io"
|
|
RREPLACES:${PN} = "opkg-nogpg opkg-collateral"
|
|
RCONFLICTS:${PN} = "opkg-collateral"
|
|
RPROVIDES:${PN} = "opkg-collateral"
|
|
|
|
FILES:libopkg = "${libdir}/*.so.* ${OPKGLIBDIR}/opkg/"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
CONFFILES:${PN} = "${sysconfdir}/opkg/opkg.conf"
|