mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-05 05:04:44 +02:00
efb0410d38
There is no need to have two assignments; also setting S from UNPACKDIR (and not vice versa) is more logical as unpack task comes first, and tasks that come after unpack use S to access unpack results. Also adjust reference test data in selftest/recipeutils to reflect changes in test recipes. (From OE-Core rev: f64b7e5fb3181734c8dde87b27e872a026261a74) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
36 lines
1022 B
BlitzBasic
36 lines
1022 B
BlitzBasic
# Copyright (C) 2018 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Minimal libssp_nonshared.a must needed for ssp to work with gcc on musl"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://stack_chk.c;beginline=1;endline=30;md5=97e59d9deee678a9332c9ddb2ab6360d"
|
|
SECTION = "libs"
|
|
|
|
# Sourced from https://github.com/intel/linux-sgx/blob/master/sdk/compiler-rt/stack_chk.c
|
|
SRC_URI = "file://stack_chk.c"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
DEPENDS = "virtual/cross-binutils \
|
|
virtual/cross-cc \
|
|
"
|
|
|
|
do_configure[noexec] = "1"
|
|
|
|
S = "${UNPACKDIR}"
|
|
|
|
do_compile() {
|
|
${CC} ${CPPFLAGS} ${CFLAGS} -fPIE -c stack_chk.c -o stack_chk.o
|
|
${AR} r libssp_nonshared.a stack_chk.o
|
|
}
|
|
do_install() {
|
|
install -Dm 0644 ${B}/libssp_nonshared.a ${D}${base_libdir}/libssp_nonshared.a
|
|
}
|
|
#
|
|
# We will skip parsing for non-musl systems
|
|
#
|
|
COMPATIBLE_HOST = ".*-musl.*"
|
|
RDEPENDS:${PN}-staticdev = ""
|
|
DEV_PKG_DEPENDENCY = ""
|
|
RRECOMMENDS:${PN}-dbg = "${PN}-staticdev (= ${EXTENDPKGV})"
|