mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 12:59:02 +02:00
741e12d5b9
These classes/recipes inherit qemu.bbclass but do not use anything from it. What they use is qemuwrapper-cross, which is needed at do_rootfs time and needs to be pulled-in by PACKAGE_WRITE_DEPS. Also, in meta/conf/layer.conf, exclude qemuwrapper-cross deps for all arch recipes that depend on it. This it ensure allarch recipes have the same signature across different machines. (From OE-Core rev: 6f3ce94f4c03e7b26f1fcdf78ea969f57717ec56) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.2 KiB
Plaintext
44 lines
1.2 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
PACKAGE_WRITE_DEPS += "qemuwrapper-cross"
|
|
|
|
GIO_MODULE_PACKAGES ??= "${PN}"
|
|
|
|
gio_module_cache_common() {
|
|
if [ "x$D" != "x" ]; then
|
|
$INTERCEPT_DIR/postinst_intercept update_gio_module_cache ${PKG} \
|
|
mlprefix=${MLPREFIX} \
|
|
binprefix=${MLPREFIX} \
|
|
libdir=${libdir} \
|
|
libexecdir=${libexecdir} \
|
|
base_libdir=${base_libdir} \
|
|
bindir=${bindir}
|
|
else
|
|
${libexecdir}/${MLPREFIX}gio-querymodules ${libdir}/gio/modules/
|
|
fi
|
|
}
|
|
|
|
python populate_packages:append () {
|
|
packages = d.getVar('GIO_MODULE_PACKAGES').split()
|
|
|
|
for pkg in packages:
|
|
bb.note("adding gio-module-cache postinst and postrm scripts to %s" % pkg)
|
|
|
|
postinst = d.getVar('pkg_postinst:%s' % pkg)
|
|
if not postinst:
|
|
postinst = '#!/bin/sh\n'
|
|
postinst += d.getVar('gio_module_cache_common')
|
|
d.setVar('pkg_postinst:%s' % pkg, postinst)
|
|
|
|
postrm = d.getVar('pkg_postrm:%s' % pkg)
|
|
if not postrm:
|
|
postrm = '#!/bin/sh\n'
|
|
postrm += d.getVar('gio_module_cache_common')
|
|
d.setVar('pkg_postrm:%s' % pkg, postrm)
|
|
}
|
|
|