mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 12:59:02 +02:00
741e12d5b9
These classes/recipes inherit qemu.bbclass but do not use anything from it. What they use is qemuwrapper-cross, which is needed at do_rootfs time and needs to be pulled-in by PACKAGE_WRITE_DEPS. Also, in meta/conf/layer.conf, exclude qemuwrapper-cross deps for all arch recipes that depend on it. This it ensure allarch recipes have the same signature across different machines. (From OE-Core rev: 6f3ce94f4c03e7b26f1fcdf78ea969f57717ec56) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
81 lines
2.7 KiB
Plaintext
81 lines
2.7 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
# This class will update the inputmethod module cache for virtual keyboards
|
|
#
|
|
# Usage: Set GTKIMMODULES_PACKAGES to the packages that needs to update the inputmethod modules
|
|
|
|
PACKAGE_WRITE_DEPS += "qemuwrapper-cross"
|
|
|
|
GTKIMMODULES_PACKAGES ?= "${PN}"
|
|
|
|
gtk_immodule_cache_postinst() {
|
|
if [ "x$D" != "x" ]; then
|
|
$INTERCEPT_DIR/postinst_intercept update_gtk_immodules_cache ${PKG} \
|
|
mlprefix=${MLPREFIX} \
|
|
binprefix=${MLPREFIX} \
|
|
libdir=${libdir} \
|
|
libexecdir=${libexecdir} \
|
|
base_libdir=${base_libdir} \
|
|
bindir=${bindir}
|
|
else
|
|
if [ ! -z `which gtk-query-immodules-2.0` ]; then
|
|
gtk-query-immodules-2.0 > ${libdir}/gtk-2.0/2.10.0/immodules.cache
|
|
fi
|
|
if [ ! -z `which gtk-query-immodules-3.0` ]; then
|
|
mkdir -p ${libdir}/gtk-3.0/3.0.0
|
|
gtk-query-immodules-3.0 > ${libdir}/gtk-3.0/3.0.0/immodules.cache
|
|
fi
|
|
fi
|
|
}
|
|
|
|
gtk_immodule_cache_postrm() {
|
|
if [ "x$D" != "x" ]; then
|
|
$INTERCEPT_DIR/postinst_intercept update_gtk_immodules_cache ${PKG} \
|
|
mlprefix=${MLPREFIX} \
|
|
binprefix=${MLPREFIX} \
|
|
libdir=${libdir} \
|
|
libexecdir=${libexecdir} \
|
|
base_libdir=${base_libdir} \
|
|
bindir=${bindir}
|
|
else
|
|
if [ ! -z `which gtk-query-immodules-2.0` ]; then
|
|
gtk-query-immodules-2.0 > ${libdir}/gtk-2.0/2.10.0/immodules.cache
|
|
fi
|
|
if [ ! -z `which gtk-query-immodules-3.0` ]; then
|
|
gtk-query-immodules-3.0 > ${libdir}/gtk-3.0/3.0.0/immodules.cache
|
|
fi
|
|
fi
|
|
}
|
|
|
|
python populate_packages:append () {
|
|
gtkimmodules_pkgs = d.getVar('GTKIMMODULES_PACKAGES').split()
|
|
|
|
for pkg in gtkimmodules_pkgs:
|
|
bb.note("adding gtk-immodule-cache postinst and postrm scripts to %s" % pkg)
|
|
|
|
postinst = d.getVar('pkg_postinst:%s' % pkg)
|
|
if not postinst:
|
|
postinst = '#!/bin/sh\n'
|
|
postinst += d.getVar('gtk_immodule_cache_postinst')
|
|
d.setVar('pkg_postinst:%s' % pkg, postinst)
|
|
|
|
postrm = d.getVar('pkg_postrm:%s' % pkg)
|
|
if not postrm:
|
|
postrm = '#!/bin/sh\n'
|
|
postrm += d.getVar('gtk_immodule_cache_postrm')
|
|
d.setVar('pkg_postrm:%s' % pkg, postrm)
|
|
}
|
|
|
|
python __anonymous() {
|
|
if not bb.data.inherits_class('native', d) and not bb.data.inherits_class('cross', d):
|
|
gtkimmodules_check = d.getVar('GTKIMMODULES_PACKAGES', False)
|
|
if not gtkimmodules_check:
|
|
bb_filename = d.getVar('FILE', False)
|
|
bb.fatal("ERROR: %s inherits gtk-immodules-cache but doesn't set GTKIMMODULES_PACKAGES" % bb_filename)
|
|
}
|
|
|