mirror of
git://git.yoctoproject.org/poky.git
synced 2025-07-19 12:59:02 +02:00
741e12d5b9
These classes/recipes inherit qemu.bbclass but do not use anything from it. What they use is qemuwrapper-cross, which is needed at do_rootfs time and needs to be pulled-in by PACKAGE_WRITE_DEPS. Also, in meta/conf/layer.conf, exclude qemuwrapper-cross deps for all arch recipes that depend on it. This it ensure allarch recipes have the same signature across different machines. (From OE-Core rev: 6f3ce94f4c03e7b26f1fcdf78ea969f57717ec56) Signed-off-by: Chen Qi <Qi.Chen@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.6 KiB
Plaintext
42 lines
1.6 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
# Inherit this class to enable or disable building and installation of manpages
|
|
# depending on whether 'api-documentation' is in DISTRO_FEATURES. Such building
|
|
# tends to pull in the entire XML stack and other tools, so it's not enabled
|
|
# by default.
|
|
PACKAGECONFIG:append:class-target = " ${@bb.utils.contains('DISTRO_FEATURES', 'api-documentation', 'manpages', '', d)}"
|
|
|
|
PACKAGE_WRITE_DEPS += "${@bb.utils.contains('DISTRO_FEATURES', 'api-documentation', 'qemuwrapper-cross', '', d)}"
|
|
|
|
# usually manual files are packaged to ${PN}-doc except man-pages
|
|
MAN_PKG ?= "${PN}-doc"
|
|
|
|
# only add man-db to RDEPENDS when manual files are built and installed
|
|
RDEPENDS:${MAN_PKG} += "${@bb.utils.contains('PACKAGECONFIG', 'manpages', 'man-db', '', d)}"
|
|
|
|
pkg_postinst:${MAN_PKG}:append () {
|
|
# only update manual page index caches when manual files are built and installed
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'manpages', 'true', 'false', d)}; then
|
|
if test -n "$D"; then
|
|
if ${@bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', 'true', 'false', d)}; then
|
|
$INTERCEPT_DIR/postinst_intercept update_mandb ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX} bindir=${bindir} sysconfdir=${sysconfdir} mandir=${mandir}
|
|
else
|
|
$INTERCEPT_DIR/postinst_intercept delay_to_first_boot ${PKG} mlprefix=${MLPREFIX}
|
|
fi
|
|
else
|
|
mandb -q
|
|
fi
|
|
fi
|
|
}
|
|
|
|
pkg_postrm:${MAN_PKG}:append () {
|
|
# only update manual page index caches when manual files are built and installed
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'manpages', 'true', 'false', d)}; then
|
|
mandb -q
|
|
fi
|
|
}
|