mirror of
git://git.yoctoproject.org/poky.git
synced 2025-08-22 00:42:05 +02:00
4eea21b7ad
Use the newly added network task flag against tasks where network access is expected. This is do_fetch, do_checkuri, do_testimage, do_testsdk and do_testsdkext. We can't disable networking in sstate tasks due to sstate downloads and also so we can report hash equivalence to the server so network access is enabled in sstate tasks. Access within build-appliance do_image is also allowed due to the use of pip, this is a poor example made rather obvious now and needs to be reworked. Network access anywhere else in any other task isn't allowed. (From OE-Core rev: 7ce1e88a3ad85bbb925bb9f7167dc0a5fd1c27f4) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.4 KiB
Plaintext
53 lines
1.4 KiB
Plaintext
# Copyright (C) 2013 - 2016 Intel Corporation
|
|
#
|
|
# Released under the MIT license (see COPYING.MIT)
|
|
|
|
# testsdk.bbclass enables testing for SDK and Extensible SDK
|
|
#
|
|
# To run SDK tests, run the commands:
|
|
# $ bitbake <image-name> -c populate_sdk
|
|
# $ bitbake <image-name> -c testsdk
|
|
#
|
|
# To run eSDK tests, run the commands:
|
|
# $ bitbake <image-name> -c populate_sdk_ext
|
|
# $ bitbake <image-name> -c testsdkext
|
|
#
|
|
# where "<image-name>" is an image like core-image-sato.
|
|
|
|
TESTSDK_CLASS_NAME ?= "oeqa.sdk.testsdk.TestSDK"
|
|
TESTSDKEXT_CLASS_NAME ?= "oeqa.sdkext.testsdk.TestSDKExt"
|
|
|
|
def import_and_run(name, d):
|
|
import importlib
|
|
|
|
class_name = d.getVar(name)
|
|
if class_name:
|
|
module, cls = class_name.rsplit('.', 1)
|
|
m = importlib.import_module(module)
|
|
c = getattr(m, cls)()
|
|
c.run(d)
|
|
else:
|
|
bb.warn('No tests were run because %s did not define a class' % name)
|
|
|
|
import_and_run[vardepsexclude] = "DATETIME BB_ORIGENV"
|
|
|
|
python do_testsdk() {
|
|
import_and_run('TESTSDK_CLASS_NAME', d)
|
|
}
|
|
addtask testsdk
|
|
do_testsdk[nostamp] = "1"
|
|
do_testsdk[network] = "1"
|
|
|
|
python do_testsdkext() {
|
|
import_and_run('TESTSDKEXT_CLASS_NAME', d)
|
|
}
|
|
addtask testsdkext
|
|
do_testsdkext[nostamp] = "1"
|
|
do_testsdkext[network] = "1"
|
|
|
|
python () {
|
|
if oe.types.boolean(d.getVar("TESTIMAGE_AUTO") or "False"):
|
|
bb.build.addtask("testsdk", None, "do_populate_sdk", d)
|
|
bb.build.addtask("testsdkext", None, "do_populate_sdk_ext", d)
|
|
}
|