mirror of
git://git.yoctoproject.org/poky.git
synced 2025-08-22 00:42:05 +02:00
ff525695f2
As stated in our top level license files, the license is MIT unless otherwise stated. Add SPDX identifers accordingly. Replace older license statementa with the standardised syntax. Also drop "All Rights Reserved" expression as it isn't used now, doesn't mean anything and is confusing. (From OE-Core rev: 081a391fe09a21265881e39a2a496e4e10b4f80b) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
40 lines
1.3 KiB
Plaintext
40 lines
1.3 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
python siteconfig_do_siteconfig () {
|
|
shared_state = sstate_state_fromvars(d)
|
|
if shared_state['task'] != 'populate_sysroot':
|
|
return
|
|
if not os.path.isdir(os.path.join(d.getVar('FILE_DIRNAME'), 'site_config')):
|
|
bb.debug(1, "No site_config directory, skipping do_siteconfig")
|
|
return
|
|
sstate_install(shared_state, d)
|
|
bb.build.exec_func('do_siteconfig_gencache', d)
|
|
sstate_clean(shared_state, d)
|
|
}
|
|
|
|
EXTRASITECONFIG ?= ""
|
|
|
|
siteconfig_do_siteconfig_gencache () {
|
|
mkdir -p ${WORKDIR}/site_config_${MACHINE}
|
|
gen-site-config ${FILE_DIRNAME}/site_config \
|
|
>${WORKDIR}/site_config_${MACHINE}/configure.ac
|
|
cd ${WORKDIR}/site_config_${MACHINE}
|
|
autoconf
|
|
rm -f ${BPN}_cache
|
|
CONFIG_SITE="" ${EXTRASITECONFIG} ./configure ${CONFIGUREOPTS} --cache-file ${BPN}_cache
|
|
sed -n -e "/ac_cv_c_bigendian/p" -e "/ac_cv_sizeof_/p" \
|
|
-e "/ac_cv_type_/p" -e "/ac_cv_header_/p" -e "/ac_cv_func_/p" \
|
|
< ${BPN}_cache > ${BPN}_config
|
|
mkdir -p ${SYSROOT_DESTDIR}${datadir}/${TARGET_SYS}_config_site.d
|
|
cp ${BPN}_config ${SYSROOT_DESTDIR}${datadir}/${TARGET_SYS}_config_site.d
|
|
|
|
}
|
|
|
|
do_populate_sysroot[sstate-interceptfuncs] += "do_siteconfig "
|
|
|
|
EXPORT_FUNCTIONS do_siteconfig do_siteconfig_gencache
|