mirror of
git://git.yoctoproject.org/poky.git
synced 2025-08-22 00:42:05 +02:00
d42904ba0c
If you build an image with lots of manpages in, then each package will run mandb inside qemu-user at rootfs time. This is a slow operation and should be done once when all of the packages have installed using an intercept instead. The call to mandb has been changed too. mandb doesn't actually allow the configuration file to be read from stdin so that was being ignored, instead write the file to a temporary file and use that. This means we then don't need to tell it where to search explicitly, and it writes the indexes to the correct paths so we don't need to move files afterwards either. Sadly we do still need to run mandb inside qemu-user, as the underlying database is a gdbm file and they are byte-order dependent. For my test case of core-image-base with api-documentation DISTRO_FEATURES and doc-pkgs IMAGE_FEATURES enabled, the performance gain is significant: core-image-base do_rootfs -1303.1s -73.6% 1771.6s -> 468.5s (From OE-Core rev: fbd8a57aa307bfda70a08cb78af3c97f05c39a3a) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.5 KiB
Plaintext
42 lines
1.5 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
# Inherit this class to enable or disable building and installation of manpages
|
|
# depending on whether 'api-documentation' is in DISTRO_FEATURES. Such building
|
|
# tends to pull in the entire XML stack and other tools, so it's not enabled
|
|
# by default.
|
|
PACKAGECONFIG:append:class-target = " ${@bb.utils.contains('DISTRO_FEATURES', 'api-documentation', 'manpages', '', d)}"
|
|
|
|
inherit qemu
|
|
|
|
# usually manual files are packaged to ${PN}-doc except man-pages
|
|
MAN_PKG ?= "${PN}-doc"
|
|
|
|
# only add man-db to RDEPENDS when manual files are built and installed
|
|
RDEPENDS:${MAN_PKG} += "${@bb.utils.contains('PACKAGECONFIG', 'manpages', 'man-db', '', d)}"
|
|
|
|
pkg_postinst:${MAN_PKG}:append () {
|
|
# only update manual page index caches when manual files are built and installed
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'manpages', 'true', 'false', d)}; then
|
|
if test -n "$D"; then
|
|
if ${@bb.utils.contains('MACHINE_FEATURES', 'qemu-usermode', 'true', 'false', d)}; then
|
|
$INTERCEPT_DIR/postinst_intercept update_mandb ${PKG} mlprefix=${MLPREFIX} binprefix=${MLPREFIX} bindir=${bindir} sysconfdir=${sysconfdir} mandir=${mandir}
|
|
else
|
|
$INTERCEPT_DIR/postinst_intercept delay_to_first_boot ${PKG} mlprefix=${MLPREFIX}
|
|
fi
|
|
else
|
|
mandb -q
|
|
fi
|
|
fi
|
|
}
|
|
|
|
pkg_postrm:${MAN_PKG}:append () {
|
|
# only update manual page index caches when manual files are built and installed
|
|
if ${@bb.utils.contains('PACKAGECONFIG', 'manpages', 'true', 'false', d)}; then
|
|
mandb -q
|
|
fi
|
|
}
|