mirror of
git://git.yoctoproject.org/poky.git
synced 2025-08-22 00:42:05 +02:00
4fda9fc667
While do_compile and do_install already have the scons_ prefix, do_configure did not. This was most likely an oversight from when it was converted from do_configure[noexec] = "1". (From OE-Core rev: c2213e0393fc589ac0ee1dd6e67ad624eb0a2706) Signed-off-by: Ola x Nilsson <olani@axis.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.3 KiB
Plaintext
41 lines
1.3 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
inherit python3native
|
|
|
|
DEPENDS += "python3-scons-native"
|
|
|
|
EXTRA_OESCONS ?= ""
|
|
# This value below is derived from $(getconf ARG_MAX)
|
|
SCONS_MAXLINELENGTH ?= "MAXLINELENGTH=2097152"
|
|
EXTRA_OESCONS:append = " ${SCONS_MAXLINELENGTH}"
|
|
scons_do_configure() {
|
|
if [ -n "${CONFIGURESTAMPFILE}" -a "${S}" = "${B}" ]; then
|
|
if [ -e "${CONFIGURESTAMPFILE}" -a "`cat ${CONFIGURESTAMPFILE}`" != "${BB_TASKHASH}" -a "${CLEANBROKEN}" != "1" ]; then
|
|
${STAGING_BINDIR_NATIVE}/scons --directory=${S} --clean PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS}
|
|
fi
|
|
|
|
mkdir -p `dirname ${CONFIGURESTAMPFILE}`
|
|
echo ${BB_TASKHASH} > ${CONFIGURESTAMPFILE}
|
|
fi
|
|
}
|
|
|
|
scons_do_compile() {
|
|
${STAGING_BINDIR_NATIVE}/scons --directory=${S} ${PARALLEL_MAKE} PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS} || \
|
|
die "scons build execution failed."
|
|
}
|
|
|
|
scons_do_install() {
|
|
${STAGING_BINDIR_NATIVE}/scons --directory=${S} install_root=${D}${prefix} PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS} install || \
|
|
die "scons install execution failed."
|
|
}
|
|
|
|
do_configure[vardepsexclude] = "SCONS_MAXLINELENGTH"
|
|
do_compile[vardepsexclude] = "SCONS_MAXLINELENGTH"
|
|
do_install[vardepsexclude] = "SCONS_MAXLINELENGTH"
|
|
|
|
EXPORT_FUNCTIONS do_configure do_compile do_install
|