mirror of
git://git.yoctoproject.org/poky.git
synced 2025-08-22 00:42:05 +02:00
d2c1494bbf
older scons do not support MAXLINELENGTH and some packages still may be using older scons, these recipes can clear SCONS_MAXLINELENGTH in them and get going. Set SCONS_MAXLINELENGTH = "" in such recipes. (From OE-Core rev: b4eaa248077305b75c551acb94223dbc524fc7a3) Signed-off-by: Khem Raj <raj.khem@gmail.com> Cc: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 34de57d12c0a752f66c962d29e5335c1035db066) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
35 lines
1.2 KiB
Plaintext
35 lines
1.2 KiB
Plaintext
inherit python3native
|
|
|
|
DEPENDS += "python3-scons-native"
|
|
|
|
EXTRA_OESCONS ?= ""
|
|
# This value below is derived from $(getconf ARG_MAX)
|
|
SCONS_MAXLINELENGTH ?= "MAXLINELENGTH=2097152"
|
|
EXTRA_OESCONS:append = " ${SCONS_MAXLINELENGTH}"
|
|
do_configure() {
|
|
if [ -n "${CONFIGURESTAMPFILE}" -a "${S}" = "${B}" ]; then
|
|
if [ -e "${CONFIGURESTAMPFILE}" -a "`cat ${CONFIGURESTAMPFILE}`" != "${BB_TASKHASH}" -a "${CLEANBROKEN}" != "1" ]; then
|
|
${STAGING_BINDIR_NATIVE}/scons --directory=${S} --clean PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS}
|
|
fi
|
|
|
|
mkdir -p `dirname ${CONFIGURESTAMPFILE}`
|
|
echo ${BB_TASKHASH} > ${CONFIGURESTAMPFILE}
|
|
fi
|
|
}
|
|
|
|
scons_do_compile() {
|
|
${STAGING_BINDIR_NATIVE}/scons --directory=${S} ${PARALLEL_MAKE} PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS} || \
|
|
die "scons build execution failed."
|
|
}
|
|
|
|
scons_do_install() {
|
|
${STAGING_BINDIR_NATIVE}/scons --directory=${S} install_root=${D}${prefix} PREFIX=${prefix} prefix=${prefix} ${EXTRA_OESCONS} install || \
|
|
die "scons install execution failed."
|
|
}
|
|
|
|
do_configure[vardepsexclude] = "SCONS_MAXLINELENGTH"
|
|
do_compile[vardepsexclude] = "SCONS_MAXLINELENGTH"
|
|
do_install[vardepsexclude] = "SCONS_MAXLINELENGTH"
|
|
|
|
EXPORT_FUNCTIONS do_compile do_install
|